之前一位小伙伴問過我URP沒有Projector，要實(shí)現(xiàn)decal功能，我后來確實(shí)注意到這一點(diǎn)，URP下的Projector有相關(guān)的插件實(shí)現(xiàn)，各位可自行百度，這里說Decal的另一種實(shí)現(xiàn)思路，屏幕空間Decal。

屏幕空間的decal思路就是在屏幕空間采樣深度圖，然后通過屏幕空間坐標(biāo)和深度值重建世界坐標(biāo)，再轉(zhuǎn)換到decal的local坐標(biāo)，算出uv即可。

先上代碼和效果圖：

Shader "Unlit/Decal"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 screenPos:TEXCOORD2;
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _CameraDepthTexture;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                o.screenPos = ComputeScreenPos(o.vertex);
                return o;
            }

            half4 frag (v2f i) : SV_Target
            {
                half2 screenPos = i.screenPos.xy/i.screenPos.w;
                float depth = UNITY_SAMPLE_DEPTH(tex2D(_CameraDepthTexture, screenPos));
                depth = Linear01Depth(depth);
                float2 positionNDC = screenPos*2-1;
                float3 farPosNDC = float3(positionNDC.xy,1)*_ProjectionParams.z;
                float4 viewPos = mul(unity_CameraInvProjection,farPosNDC.xyzz);
                viewPos.xyz*=depth;
                float4 worldPos = mul(UNITY_MATRIX_I_V,viewPos);
                float3 localPos = mul(unity_WorldToObject,worldPos).xyz;
                clip(0.5 - abs(localPos));
                float2 uv = localPos.xz+0.5;
                return tex2D(_MainTex,uv);
            }
            ENDCG
        }
    }
}

直接使用此代碼需要將渲染隊(duì)列設(shè)置在AlphaTest之后，這里省事兒沒寫~嘿嘿。

效果如下：

接下來講一下實(shí)現(xiàn)過程，當(dāng)然，嫌我啰嗦直接拷貝用就可以，但是有個問題，需要繪制深度圖或者在URP中有CopyDepth，并且由于URP的正向渲染中沒有DepthNormalMap，所以這里為了省事也沒有對法線進(jìn)行處理，需要的可自行添加~

過程主要分三步：

1.采樣深度圖

首先采樣深度圖這里，通過頂點(diǎn)著色器調(diào)用ComputeScreenPos方法得到一個可以線性插值的屏幕坐標(biāo)半成品，然后在片元著色器完成屏幕坐標(biāo)計(jì)算。

采樣深度圖需要注意要將采樣的結(jié)果進(jìn)行Linear01Depth，因?yàn)樯疃葓D中的深度不是線性的。離攝像機(jī)越近，深度值越小，反之越大。但是看FrameDebugger的時候正好相反，不知道為啥，可能是反過來讓用戶體驗(yàn)更好，也可能是抽風(fēng)。

正確的深度如圖：

FrameDebugger的深度如下：

這里還有個容易誤導(dǎo)的地方需要注意一下，URP下FrameDebugger的深度圖是被倒置的，不知道為啥，總之不要被FrameDebugger迷惑就行。

2.重建世界坐標(biāo)

重建世界坐標(biāo)的方法有很多，這里采用的是構(gòu)建此坐標(biāo)在遠(yuǎn)裁切面的投影位置（即相機(jī)到該投影位置的向量)的投影空間，然后轉(zhuǎn)換到相機(jī)空間，乘采樣得到的深度值，就得到了相機(jī)空間該深度的坐標(biāo)，然后轉(zhuǎn)換到世界坐標(biāo)。其他方法可以自行百度。

3.轉(zhuǎn)換成uv坐標(biāo)并采樣

世界坐標(biāo)轉(zhuǎn)換為模型坐標(biāo)（localpos），范圍（-0.5~0.5），+0.5映射到uv(0~1)即可。

基于屏幕空間的Decal方便隨時用在任何物體上（寫入深度的物體），相對于Projector，不需要被投影的對象shader支持，也不像直接用片容易z-fighting，但是缺點(diǎn)也很明顯，需要深度圖，如果本身項(xiàng)目中就有深度圖繪制的需求，或者用的URP的CopyDepth，那這種方式可能更適用，但是---但是，就是之前說的，沒有處理法線，效果就是如下：

從下往上看，反面不應(yīng)該產(chǎn)生Decal的地方也產(chǎn)生了，所以大家根據(jù)情況選擇適用的方案哦~

總結(jié)

以上是生活随笔為你收集整理的基于URP的ScreenSpaceDecal的实现（其实和URP没啥关系）的全部內(nèi)容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網(wǎng)站內(nèi)容還不錯，歡迎將生活随笔推薦給好友。