原文地址：https://ethereum.org/token

代幣

我們將要?jiǎng)?chuàng)建一個(gè)數(shù)字令牌。在以太坊生態(tài)系統(tǒng)中數(shù)字令牌可以代表任何交易物品：幣，忠誠點(diǎn)，黃金券，白條，游戲物品等。所有令牌都通過標(biāo)準(zhǔn)方式，實(shí)現(xiàn)了一些基本功能。這就意味著，你的令牌會(huì)立即兼容以太坊錢包和其他客戶端，或使用了相同標(biāo)準(zhǔn)的合約。

最簡單令牌

標(biāo)準(zhǔn)令牌合約會(huì)很復(fù)雜。但是本質(zhì)上，實(shí)現(xiàn)最基礎(chǔ)的令牌代碼如下：

contract MyToken {
    /* 創(chuàng)建所有賬戶余額數(shù)組 */
    mapping (address => uint256) public balanceOf;

    /*初始化合約，將最初的令牌打入創(chuàng)建者的賬戶中*，此處由于官方文檔版本不夠新，沒有public，經(jīng)驗(yàn)證是無法正常運(yùn)行的/
    function MyToken( uint256 initialSupply) public {
        balanceOf[msg.sender] = initialSupply;              // 給創(chuàng)建者所有初始令牌
    }

    /* 發(fā)送代幣 */
    function transfer(address _to, uint256 _value) {
        require(balanceOf[msg.sender] >= _value);           // 檢查發(fā)送者是否擁有足夠的幣
        require(balanceOf[_to] + _value >= balanceOf[_to]); // 檢查是否越界
        balanceOf[msg.sender] -= _value;                    // 從發(fā)送者扣幣
        balanceOf[_to] += _value;                           // 給接受者加相同數(shù)額的幣
    }
}

代碼

但如果想復(fù)制粘貼更完整一點(diǎn)的代碼，就用這段：

pragma solidity ^0.4.16;

interface tokenRecipient { function receiveApproval(address _from, uint256 _value, address _token, bytes _extraData) public; }

contract TokenERC20 {
    // 令牌的公有變量
    string public name;
    string public symbol;
    uint8 public decimals = 18;
    // 18 decimals 極力推薦使用默認(rèn)值，盡量別改
    uint256 public totalSupply;

    // 創(chuàng)建所有賬戶余額數(shù)組
    mapping (address => uint256) public balanceOf;
    mapping (address => mapping (address => uint256)) public allowance;

    // 在區(qū)塊鏈上創(chuàng)建一個(gè)公共事件，它觸發(fā)就會(huì)通知所有客戶端
    event Transfer(address indexed from, address indexed to, uint256 value);

    // 通知客戶端銷毀數(shù)額
    event Burn(address indexed from, uint256 value);

    /**
     * 合約方法
     *
     * 初始化合約，將最初的令牌打入創(chuàng)建者的賬戶中
     */
    function TokenERC20(
        uint256 initialSupply,
        string tokenName,
        string tokenSymbol
    ) public {
        totalSupply = initialSupply * 10 ** uint256(decimals);  // 更新總發(fā)行量
        balanceOf[msg.sender] = totalSupply;                // 給創(chuàng)建者所有初始令牌
        name = tokenName;                                   // 設(shè)置顯示名稱
        symbol = tokenSymbol;                               // 設(shè)置顯示縮寫，例如比特幣是BTC
    }

    /**
     * 內(nèi)部轉(zhuǎn)賬，只能被該合約調(diào)用
     */
    function _transfer(address _from, address _to, uint _value) internal {
        // 如果轉(zhuǎn)賬到 0x0 地址. 使用 burn() 替代
        require(_to != 0x0);
        // 檢查發(fā)送者是否擁有足夠的幣
        require(balanceOf[_from] >= _value);
        // 檢查越界
        require(balanceOf[_to] + _value > balanceOf[_to]);
        // 將此信息保存用于將來確認(rèn)
        uint previousBalances = balanceOf[_from] + balanceOf[_to];
        // 從發(fā)送者扣幣
        balanceOf[_from] -= _value;
        // 給接收者加相同數(shù)量幣
        balanceOf[_to] += _value;
        Transfer(_from, _to, _value);
        // 使用assert是為了使用靜態(tài)分析找到代碼bug. 它永遠(yuǎn)不會(huì)失敗
        assert(balanceOf[_from] + balanceOf[_to] == previousBalances);
    }

    /**
     * 發(fā)送令牌
     *
     * 從你的賬戶發(fā)送個(gè)`_value` 令牌到 `_to` 
     *
     * @param _to 接收地址
     * @param _value 發(fā)送數(shù)量
     */
    function transfer(address _to, uint256 _value) public {
        _transfer(msg.sender, _to, _value);
    }

    /**
     * 從其他地址發(fā)送令牌
     *
     * 從`_from` 發(fā)送 `_value` 個(gè)令牌到 `_to` 
     *
     * @param _from 發(fā)送地址
     * @param _to 接收地址
     * @param _value 發(fā)送數(shù)量
     */
    function transferFrom(address _from, address _to, uint256 _value) public returns (bool success) {
        require(_value <= allowance[_from][msg.sender]);     // Check allowance
        allowance[_from][msg.sender] -= _value;
        _transfer(_from, _to, _value);
        return true;
    }

    /**
     * 設(shè)置其他地址限額
     *
     * 允許 `_spender` 以你的名義使用不超過 `_value`令牌 
     *
     * @param _spender 授權(quán)使用的地址
     * @param _value 最大可使用數(shù)量
     */
    function approve(address _spender, uint256 _value) public
        returns (bool success) {
        allowance[msg.sender][_spender] = _value;
        return true;
    }

    /**
     * 設(shè)置其他地址限額，并通知
     *
     * 允許 `_spender`以你的名義使用最多 `_value`個(gè)令牌, 然后通知合約
     *
     * @param _spender 授權(quán)使用的地址
     * @param _value  最大使用額度
     * @param _extraData 發(fā)送給已經(jīng)證明的合約額外信息
     */
    function approveAndCall(address _spender, uint256 _value, bytes _extraData)
        public
        returns (bool success) {
        tokenRecipient spender = tokenRecipient(_spender);
        if (approve(_spender, _value)) {
            spender.receiveApproval(msg.sender, _value, this, _extraData);
            return true;
        }
    }

    /**
     * 銷毀令牌
     *
     * 永久除去 `_value` 個(gè)令牌，不可恢復(fù)
     *
     * @param _value 數(shù)量
     */
    function burn(uint256 _value) public returns (bool success) {
        require(balanceOf[msg.sender] >= _value);   // Check if the sender has enough
        balanceOf[msg.sender] -= _value;            // Subtract from the sender
        totalSupply -= _value;                      // Updates totalSupply
        Burn(msg.sender, _value);
        return true;
    }

    /**
     * 從其他賬戶銷毀令牌
     *
     * 以‘_from’的名義，移除其 `_value`個(gè)令牌，不可恢復(fù).
     *
     * @param _from 地址
     * @param _value 銷毀數(shù)量
     */
    function burnFrom(address _from, uint256 _value) public returns (bool success) {
        require(balanceOf[_from] >= _value);                // Check if the targeted balance is enough
        require(_value <= allowance[_from][msg.sender]);    // Check allowance
        balanceOf[_from] -= _value;                         // Subtract from the targeted balance
        allowance[_from][msg.sender] -= _value;             // Subtract from the sender's allowance
        totalSupply -= _value;                              // Update totalSupply
        Burn(_from, _value);
        return true;
    }
}

給我的ETH捐贈(zèng)地址：0xdc834D429b3098f0568Af873c2d73b08790BF677

創(chuàng)建自己的加密貨幣MNC——以太坊代幣（二）

創(chuàng)建自己的區(qū)塊鏈游戲SLOT——以太坊代幣（三）

總結(jié)

以上是生活随笔為你收集整理的创建自己的加密货币——以太坊代币（一）的全部內(nèi)容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網(wǎng)站內(nèi)容還不錯(cuò)，歡迎將生活随笔推薦給好友。