熟悉財務和投資的小伙伴，對 NPV 一定不會陌生，NPV，即凈現值，它是衡量投資收益的重要指標，一般來說，一項投資的凈現值越大，收益越好。

微軟Office LTSC 2021專業增強版 簡體中文批量許可版 2023年06月更新

• 類型：辦公軟件
• 大小：2.2GB
• 語言：簡體中文
• 時間：2023-06-15

查看詳情

Excel 中的 NPV 函數就是專門為計算凈現值量身定制的。

但，就是這樣一個看似平淡正經的函數，竟也硬生生讓 Excel 大佬們玩出了花活！

想知道 NPV 函數的另類用法嗎？

跟上小花的節奏，帶你領略不一樣的 NPV 函數！

1、交叉求差的行家

小 K 管理四家門店，每天都需要通過各門店的收支表計算總利潤，每個門店的收支都用正數表示，如下圖，如何設置 C10 單元格的計算公式才最簡潔呢？

常規的思路肯定是用 SUMIF 函數來處理，公式如下：

=SUM(C2:C9)-2*SUMIF(B2:B9,"支出",C2:C9)

盡管這個公式相較于兩個 SUMIF 函數相減的公式，已經簡化了許多，但如果你使用 NPV 函數來處理這個問題，其公式的間潔程度絕對能驚掉你的下巴！

不信，一起瞧瞧？

NPV 隔行求差公式：

=-NPV(-2,C2:C9)

公式說明：

該公式是基于 NPV 函數的計算原理和數學邏輯而設置的。

首先，我們需要先了解 NPV 函數的計算原理，即參數 2 的每個值 value 都乘以 1/（1+rate）的指定次放（當前值的序數值）再求和。

公式中，我們將 rate 設定為-2，于是 1/（1+rate）等于-1。

基于-1 的奇數次方為-1、偶數次方為 1 這一原理，NPV 函數第二參數的每一個奇數項取其相反數，偶數項取其本身，從而實現交叉求差運算。

由于這樣計算的結果是收入為負、支出為正，因此需要在公式前添加負號。

同時由于 NPV 輸出結果默認為貨幣，所以需重新設置單元格數字格式為【常規】。

2、混合文本取數能手

混合文本取數是一個 Excel 公式難題，你一定見過很多不同的解法，但你可能不知道，NPV 函數也可以解決這個問題，特別是從一堆混亂數據中提取所有數值并進行組合，NPV 可謂得心應手。

如下例，由于記錄過程時間倉促，導致客戶信息和客戶電話號碼混雜，且格式隨意，沒有明確規則，唯一能確定的是，客戶的電話號碼是記錄完全、順序無誤的。

這種情況下，該如何提取客戶電話號碼呢？

公式如下：

{=(--MID(NPV(9,IFERROR(--MID(A2,ROW($1:$100),1),""),1),3,100)-1)/10}

公式說明：

①ROW($1:$100)：返回 1:100 的有序數組

②MID(A2,①,1)：逐一提取 A2 中的每個字符

③--②：將 MID 提取的數字轉化成數值

④IFERROR(③,"")：MID 提取的非數字通過雙負號轉化為數值或出現拼寫錯誤#NAME?，此處使用 IFERROR 將其轉換為空，于是 MID 提出的所有字符中，僅所有數字被保留，其余均為空。

⑤NPV(9,④,1)：將 rate 設定為 9，于是 1/（1+rate）等于 1/10，④中所有數字 {1;7;7;8;9;1;2;3;2;4;5} 依次除以 10，100，1000......，得到 {0.1;0.07;0.007;0.0008;0.00009;......}，相加后得到 0.17789123245，即實現了將所有數字在小數點后依次排列的效果。為避免最后一位數為 0，導致后續計算出錯，NPV 增加一個 value 值 1，從而實現在數字串的最后一位后添加數字 1，0.17789123245 被轉化為 0.177891232451。

⑥MID(⑤,3,100)：提取小數點后的所有數字

⑦--⑥：同③，將 MID 提取的數字轉化成數值

⑧{=(⑦-1)/10}：去除⑤中額外添加的尾數 1。最外圍的大括號表示這是一個數組公式，需要同時按 Ctrl+Shift+Enter 才能正確計算。

3、數字倒排大師

有朋友問過小花，如何把 10 個數字組成的編碼倒序排列？

小花給出的答案讓他震驚不已！沒錯，就是 NPV 函數。

公式如下：

{=NPV(-0.9,--MID(A2,ROW($1:$10),1))/10}

公式說明：

MID (A2,ROW ($1:$10),1) 將 A2 單元格中的數字逐一提取出來，通過雙負號「--」將文本型數字轉化為數值型數字，以便 NPV 進行計算。

將 NPV 函數的參數 rate 設定為-0.9，于是 1/（1+rate）等于 10，A2 中的所有數字被依次乘以 10,100,1000......，再相加，就實現了將第 1 個數字填列在十位上，第 2 個數字填列在百位數，第 3 個數字填列在千位上，以此類推。最后將公式的整體除以 10，即可完成數字倒排。

以上就是小花分享的關于 NPV 函數的三種另類用法，你學會了嗎？回顧一下吧：

? rate 設定為-2，可實現交叉求差；

?rate 設定為 9，能夠完成混合文本取數；

?rate 設定為-0.9，輕松拿下數字倒排。

本文來自微信公眾號：秋葉 Excel （ID：excel100），作者：小花

以上就是Excel 中 NPV 函數使用技巧分享，希望大家喜歡，請繼續關注風君子博客。

相關推薦：

excel怎么計算NPV凈現值? 凈現值npv計算公式的使用教程

excel表格數據怎么算概率? excel函數計算概率的教程

excel函數怎么判斷是否在兩個數之間?

總結

以上是生活随笔為你收集整理的excel中npv公式怎么用? Excel 中 NPV 函数使用技巧分享的全部內容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網站內容還不錯，歡迎將生活随笔推薦給好友。