代碼:

Function OpenExcelFile(sPath As String, ByVal sFileName As String, bDisplay As Boolean, sPwd As String) As Integer
? ? '打開Excel文件
? ? 'Ver 1.05
? ? '完成時間：2007.12.01
? ? '設計：美猴王軟件工作室 www.okexcel.com.cn
? ? '參數說明：
? ? 'sPath:文件絕對路徑；sFileName:Excel文件名；bDisplay:True顯示錯誤信息；sPwd:文件打開密碼
? ? '返回值：-1:同名文件已經打開；-2:文件不存在或密碼錯誤；0:成功打開；1:文件已經被打開
? ? Dim bOpen As Boolean
? ? Dim sFullName As String
? ? On Error Resume Next
? ? If InStr(LCase(sFileName), ".xls") = 0 Then sFileName = sFileName & ".xls"
? ? sFullName = Workbooks(sFileName).FullName
? ? '檢查是否已經打開同名的Excel文件
? ? '如果有sFullName不為空
? ? On Error GoTo 0
? ? bOpen = False
? ? If sFullName <> "" Then
? ?? ???If LCase(sFullName) = LCase(sPath & "/" & sFileName) Then
? ?? ?? ?? ?bOpen = True
? ?? ?? ?? ?'判斷已經打開的同名文件是否本次需要打開的文件
? ?? ?? ?? ?OpenExcelFile = 1
? ?? ?? ?? ?'文件已經被打開
? ?? ???Else
? ?? ?? ?? ?If bDisplay Then
? ?? ?? ?? ?? ? MsgBox "請首先關閉“" & sFileName & "”文件！" & Chr(13) & "不能同時打開同名文件，這是Excel的規定！", vbOKOnly + vbExclamation, "文件的打開錯誤"
? ?? ?? ?? ?End If
? ?? ?? ?? ?bOpen = True
? ?? ?? ?? ?OpenExcelFile = -1
? ?? ?? ?? ?'不能同時打開同名文件，這是Excel的規定
? ?? ???End If
? ? End If
? ? If Not bOpen Then
? ?? ???On Error GoTo errOpen
? ?? ???Workbooks.Open Filename:=sPath & "/" & sFileName, Password:=sPwd
? ?? ???On Error GoTo 0
? ?? ???OpenExcelFile = 0
? ?? ???'成功打開文件
? ? End If
? ? Exit Function
errOpen:
? ? If bDisplay Then MsgBox Err.Description, vbOKOnly + vbExclamation, "文件的打開錯誤"
? ? OpenExcelFile = -2
? ? '文件不存在或密碼錯誤
? ? On Error GoTo 0
End Function

總結

以上是生活随笔為你收集整理的【常用自定义函数001】VBA高容错性地打开文件的全部內容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網站內容還不錯，歡迎將生活随笔推薦給好友。