轉載：http://blog.csdn.net/l_thread/article/details/6020036

?

開始看start.s中的代碼，又一句.balignl 16,0xdeadbeef，不知什么意思，網上搜了一下了解到這條命令的作用如下：

.balign[wl] abs-expr, abs-expr, abs-expr

增加位置計數器(在當前子段)使它指向規定的存儲邊界。第一個表達式參數(結果必須是純粹的數字)是必需參數：邊界基準,單位為字節。例如，‘.balign 8’向后移動位置計數器直至計數器的值等于8的倍數。如果位置計數器已經是8的倍數，則無需移動。第2個表達式參數(結果必須是純粹的數字)給出填充字節的值，用這個值填充位置計數器越過的地方。第2個參數(和逗點)可以省略。如果省略它，填充字節的值通常是0。但在某些系統上，如果本段標識為包含代碼，而填充值被省略,則使用no-op指令填充空白區。第3個參數的結果也必須是純粹的數字，這個參數是可選的。如果存在第3個參數，它代表本對齊命令允許跳過字節數的最大值。如果完成這個對齊需要跳過的字節數比規定的最大值還多,則根本無法完成對齊。您可以在邊界基準參數后簡單地使用兩個逗號，以省略填充值參數(第二參數)；如果您在想在適當的時候，對齊操作自動使用no-op指令填充，本方法將非常奏效。

.balignw和.balignl是.balign命令的變化形式。.balignw使用2個字節來填充空白區。.balignl使用4字節來填充。例如,.balignw 4,0x368d將地址對齊到4的倍數，如果它跳過2個字節，GAS將使用0x368d填充這2個字節(字節的確切存放位置視處理器的存儲方式而定)。
如果它跳過1或3個字節,則填充值不明確。

?

---

大多數bootloader都分為stage1和stage2兩部分，u-boot也不例外。依賴于CPU體系結構的代碼（如設備初始化代碼等）通常都放在stage1且可以用匯編語言來實現，而stage2則通常用C語言來實現，這樣可以實現復雜的功能，而且有更好的可讀性和移植性。
1、Stage1 start.S代碼結構?
u-boot的stage1代碼通常放在start.S文件中，他用匯編語言寫成，其主要代碼部分如下：
（1）定義入口。由于一個可執行的Image必須有一個入口點，并且只能有一個全局入口，通常這個入口放在ROM（Flash）的0x0地址，因此，必須通知編譯器以使其知道這個入口，該工作可通過修改連接器腳本來完成。
（2）設置異常向量（Exception Vector）。
（3）設置CPU的速度、時鐘頻率及終端控制寄存器。
（4）初始化內存控制器。
（5）將ROM中的程序復制到RAM中。
（6）初始化堆棧。
（7）轉到RAM中執行，該工作可使用指令ldr pc來完成。
2、Stage2 C語言代碼部分
lib_arm/board.c中的start arm boot是C語言開始的函數也是整個啟動代碼中C語言的主函數，同時還是整個u-boot（armboot）的主函數，該函數只要完成如下操作：
（1）調用一系列的初始化函數。
（2）初始化Flash設備。
（3）初始化系統內存分配函數。
（4）如果目標系統擁有NAND設備，則初始化NAND設備。
（5）如果目標系統有顯示設備，則初始化該類設備。
（6）初始化相關網絡設備，填寫IP、MAC地址等。
（7）進去命令循環（即整個boot的工作循環），接受用戶從串口輸入的命令，然后進行相應的工作。
3、U-Boot的啟動順序(示例，其他u-boot版本類似)
cpu/arm920t/start.S

@文件包含處理

#include <config.h>
@由頂層的mkconfig生成，其中只包含了一個文件：configs/<頂層makefile中6個參數的第1個參數>.h?
#include <version.h>
#include <status_led.h>

?

注：ARM微處理器支持字節（8位）、半字（16位）、字（32位）3種數據類型
@向量跳轉表，每條占四個字節（一個字），地址范圍為0x0000 0000～@0x0000 0020
@ARM體系結構規定在上電復位后的起始位置，必須有8條連續的跳

@轉指令，通過硬件實現。他們就是異常向量表。ARM在上電復位后，@是從0x00000000開始啟動的，其實如果bootloader存在，在執行

@下面第一條指令后，就無條件跳轉到start_code，下面一部分并沒@執行。設置異常向量表的作用是識別bootloader。以后系統每當有@異常出現，則CPU會根據異常號，從內存的0x00000000處開始查表@做相應的處理

?

.globl _start?
@_start是GNU匯編器的默認入口標簽，.globl將_start聲明為外部程序可訪問的標簽，.globl是GNU匯編的保留關鍵字，前面加點是GNU匯編的語法
_start: b start_code @0x00
@ARM上電后執行的第一條指令，也即復位向量，跳轉到start_code

@reset用b，就是因為reset在MMU建立前后都有可能發生
@其他的異常只有在MMU建立之后才會發生
ldr pc, _undefined_instruction
ldr pc, _software_interrupt
ldr pc, _prefetch_abort
ldr pc, _data_abort
ldr pc, _not_used
ldr pc, _irq
ldr pc, _fiq

@對于ARM數據從內存到CPU之間的移動只能通過L/S指令，如：ldr r0,0x12345678為把0x12345678內存中的數據寫到r0中，還有一個就是ldr偽指令，如：ldr r0,=0x12345678為把0x12345678地址寫到r0中，mov只能完成寄存器間數據的移動，而且立即數長度限制在8位

_undefined_instruction: .word undefined_instruction
_software_interrupt: .word software_interrupt
_prefetch_abort: .word prefetch_abort
_data_abort: .word data_abort
_not_used: .word not_used
_irq: .word irq
_fiq: .word fiq
@.word為GNU ARM匯編特有的偽操作，為分配一段字內存單元（分配的單元為字對齊的），可以使用.word把標志符作為常量使用。如_fiq:.word fiq即把fiq存入內存變量_fiq中，也即是把fiq放到地址_fiq中。

.balignl 16,0xdeadbeef
@.balignl是.balign的變體

@?.align偽操作用于表示對齊方式：通過添加填充字節使當前位置

@滿足一定的對齊方式。.balign的作用同.align。
@?.align {alignment} {,fill} {,max}
@?其中：alignment用于指定對齊方式，可能的取值為2的次

@冪，缺省為4。fill是填充內容，缺省用0填充。max是填充字節@數最大值，如果填充字節數超過max,?就不進行對齊,例如：
@?.align 4

【參考好野人的窩，于關u-boot中的.balignl 16,0xdeadbeef的理解http://haoyeren.blog.sohu.com/84511571.html】

@TEXT_BASE在開發板相關的目錄中的config.mk文檔中定義, 他定

@義了代碼在運行時所在的地址, 那么_TEXT_BASE中保存了這個地

@址（這個TEXT_BASE怎么來的還不清楚）

.globl _armboot_start
_armboot_start:
.word _start
@用_start來初始化_armboot_start。（為什么要這么定義一下還不明白）

@下面這些是定義在開發板目錄鏈接腳本中的

.globl _bss_start?
_bss_start:
.word __bss_start
@__bss_start定義在和開發板相關的u-boot.lds中，_bss_start保存的是__bss_start標號所在的地址。

.globl _bss_end
_bss_end:
.word _end
@同上，這樣賦值是因為代碼所在地址非編譯時的地址，直接取得該標號對應地址。

@中斷的堆棧設置

#ifdef CONFIG_USE_IRQ

.globl IRQ_STACK_START
IRQ_STACK_START:
.word 0x0badc0de

.globl FIQ_STACK_START
FIQ_STACK_START:
.word 0x0badc0de
#endif

@復位后執行程序
@真正的初始化從這里開始了。其實在CPU一上電以后就是跳到這里執行的
reset:

@更改處理器模式為管理模式
@對狀態寄存器的修改要按照：讀出-修改-寫回的順序來執行
@
31 30 29 28 --- 7 6 - 4 3 2 1 0
N Z C V I F M4 M3 M2 M1 M0
0 0 0 0 0 User26 模式
0 0 0 0 1 FIQ26 模式
0 0 0 1 0 IRQ26 模式
0 0 0 1 1 SVC26 模式
1 0 0 0 0 User 模式
1 0 0 0 1 FIQ 模式
1 0 0 1 0 IRQ 模式
1 0 0 1 1 SVC 模式
1 0 1 1 1 ABT 模式
1 1 0 1 1 UND 模式
1 1 1 1 1 SYS 模式

mrs r0,cpsr
@將cpsr的值讀到r0中
bic r0,r0,#0x1f
@清除M0~M4
orr r0,r0,#0xd3
@禁止IRQ,FIQ中斷，并將處理器置于管理模式
msr cpsr,r0

@以下是點燈了，這里應該會牽涉到硬件設置，移植的時候應該可以不要
bl coloured_LED_init
bl red_LED_on

@針對AT91RM9200進行特殊處理
#if defined(CONFIG_AT91RM9200DK) || defined(CONFIG_AT91RM9200EK)

ldr r0, =_start
ldr r1, =0x0
mov r2, #16
copyex:
subs r2, r2, #1
@sub帶上了s用來更改進位標志，對于sub來說，若發生借位則C標志置0，沒有則為1，這跟adds指令相反！要注意。
ldr r3, [r0], #4
str r3, [r1], #4
bne copyex
#endif

@針對S3C2400和S3C2410進行特殊處理
@CONFIG_S3C2400、CONFIG_S3C2410等定義在include/configs/下不同開發板的頭文件中
#if defined(CONFIG_S3C2400) || defined(CONFIG_S3C2410)

@關閉看門狗定時器的自動復位功能并屏蔽所有中斷，上電后看門狗為開，中斷為關
# if defined(CONFIG_S3C2400)
# define pWTCON 0x15300000
# define INTMSK 0x14400008
# define CLKDIVN 0x14800014
#else?@s3c2410的配置
# define pWTCON 0x53000000
@pWTCON定義為看門狗控制寄存器的地址（s3c2410和s3c2440相同）
# define INTMSK 0x4A000008
@INTMSK定義為主中斷屏蔽寄存器的地址（s3c2410和s3c2440相同）
# define INTSUBMSK 0x4A00001C
@INTSUBMSK定義為副中斷屏蔽寄存器的地址（s3c2410和s3c2440相同）
# define CLKDIVN 0x4C000014
@CLKDIVN定義為時鐘分頻控制寄存器的地址（s3c2410和s3c2440相同）
# endif
@至此寄存器地址設置完畢

ldr r0, =pWTCON
mov r1, #0x0
str r1, [r0]
@對于S3C2440和S3C2410的WTCON寄存器的[0]控制允許或禁止看門狗定時器的復位輸出功能，設置為"0"禁止復位功能。

mov r1, #0xffffffff
ldr r0, =INTMSK
str r1, [r0]
# if defined(CONFIG_S3C2410)
ldr r1, =0x3ff?@2410好像應該為7ff才對（不理解uboot為何是這個數字）
ldr r0, =INTSUBMSK
str r1, [r0]
# endif
@對于S3C2410的INTMSK寄存器的32位和INTSUBMSK寄存器的低11位每一位對應一個中斷，相應位置"1"為不響應相應的中斷。對于S3C2440的INTSUBMSK有15位可用，所以應該為0x7fff了。

ldr r0, =CLKDIVN
mov r1, #3
str r1, [r0]
@時鐘分頻設置，FCLK為核心提供時鐘，HCLK為AHB（ARM920T,內存@控制器，中斷控制器，LCD控制器，DMA和主USB模塊）提供時鐘，@PCLK為APB（看門狗、IIS、I2C、PWM、MMC、ADC、UART、GPIO、@RTC、SPI）提供時鐘。分頻數一般選擇1：4：8，所以HDIVN=2,PDIVN=1，@CLKDIVN=5，這里僅僅是配置了分頻寄存器，關于MPLLCON的配置肯@定寫在lowlevel_init.S中了
@歸納出CLKDIVN的值跟分頻的關系：
@0x0 = 1:1:1 , 0x1 = 1:1:2 , 0x2 = 1:2:2 , 0x3 = 1:2:4, 0x4 = 1:4:4, 0x5 = 1:4:8, 0x6 = 1:3:3,
0x7 = 1:3:6
@S3C2440的輸出時鐘計算式為:Mpll=(2*m*Fin)/(p*2^s)
S3C2410的輸出時鐘計算式為:Mpll=(m*Fin)/(p*2^s)
m=M(the value for divider M)+8;p=P(the value for divider P)+2
M,P,S的選擇根據datasheet中PLL VALUE SELECTION TABLE表格進行，

我的開發板晶振為16.9344M，所以輸出頻率選為：399.65M的話M=0x6e,P=3,S=1
@s3c2440增加了攝像頭,其FCLK、HCLK、PCLK的分頻數還受到CAMDIVN[9]（默認為0）,CAMDIVN[8]（默認為0）的影響
#endif

@選擇是否初始化CPU
#ifndef CONFIG_SKIP_LOWLEVEL_INIT
bl cpu_init_crit
@執行CPU初始化，BL完成跳轉的同時會把后面緊跟的一條指令地址保存到連接寄存器LR（R14）中。以使子程序執行完后正常返回。
#endif

@調試階段的代碼是直接在RAM中運行的，而最后需要把這些代碼?@固化到Flash中，因此U-Boot需要自己從Flash轉移到
@RAM中運行，這也是重定向的目的所在。
@通過adr指令得到當前代碼的地址信息：如果U-boot是從RAM?@開始運行，則從adr,r0,_start得到的地址信息為
@r0=_start=_TEXT_BASE=TEXT_BASE=0x33F80000;?@如果U-boot從Flash開始運行，即從處理器對應的地址運行，
@則r0=0x0000,這時將會執行copy_loop標識的那段代碼了。
@?_TEXT_BASE?定義在board/smdk2410/config.mk中

#ifndef CONFIG_SKIP_RELOCATE_UBOOT
relocate:?
adr r0, _start?
ldr r1, _TEXT_BASE?
cmp r0, r1?
beq stack_setup
ldr r2, _armboot_start
@_armboot_start為_start地址
ldr r3, _bss_start
@_bss_start為數據段地址
sub r2, r3, r2?
add r2, r0, r2

copy_loop:
ldmia r0!, {r3-r10}

@從源地址[r0]讀取8個字節到寄存器,每讀一個就更新一次r0地址
@ldmia:r0安字節增長
stmia r1!, {r3-r10}?
@LDM(STM)用于在寄存器所指的一片連續存儲器和寄存器列表的寄存@器間進行數據移動，或是進行壓棧和出棧操作。
@格式為：LDM(STM){條件}{類型}基址寄存器{！}，寄存器列表{^}
@對于類型有以下幾種情況： IA 每次傳送后地址加1，用于移動數

@據塊
IB 每次傳送前地址加1，用于移動數據塊
DA 每次傳送后地址減1，用于移動數據塊
DB 每次傳送前地址減1，用于移動數據塊
FD 滿遞減堆棧，用于操作堆棧（即先移動指針再操作數據，相當于DB）
ED 空遞減堆棧，用于操作堆棧（即先操作數據再移動指針，相當于DA）
FA 滿遞增堆棧，用于操作堆棧（即先移動指針再操作數據，相當于IB）
EA 空遞增堆棧，用于操作堆棧（即先操作數據再移動指針，相當于IA）
（這里是不是應該要涉及到NAND或者NOR的讀寫？沒有看出來）

cmp r0, r2?
ble copy_loop
#endif /* CONFIG_SKIP_RELOCATE_UBOOT */

@初始化堆棧
stack_setup:

ldr r0, _TEXT_BASE

@獲取分配區域起始指針，

sub r0, r0, #CONFIG_SYS_MALLOC_LEN

@CFG_MALLOC_LEN=128*1024+CFG_ENV_SIZE=128*1024+0x1@0000=192K

sub r0, r0, #CONFIG_SYS_GBL_DATA_SIZE

@CFG_GBL_DATA_SIZE 128---size in bytes reserved for initial data?用來存儲開發板信息
#ifdef CONFIG_USE_IRQ

@這里如果需要使用IRQ,?還有給IRQ保留堆?？臻g,?一般不使用.
sub r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
#endif
sub sp, r0, #12

@該部分將未初始化數據段_bss_start----_bss_end中的數據?@清零
clear_bss:
ldr r0, _bss_start
ldr r1, _bss_end
mov r2, #0x00000000

clbss_l:str r2, [r0]
add r0, r0, #4
cmp r0, r1
ble clbss_l

@跳到階段二C語言中去
ldr pc, _start_armboot

_start_armboot: .word start_armboot
@start_armboot在/lib_arm/中，到這里因該是第一階段已經完成了吧，下面就要去C語言中執行第二階段了吧

@CPU初始化

@在"relocate: "之前被調用

#ifndef CONFIG_SKIP_LOWLEVEL_INIT
cpu_init_crit:

@初始化CACHES
mov r0, #0
mcr p15, 0, r0, c7, c7, 0?
mcr p15, 0, r0, c8, c7, 0

@關閉MMU和CACHES
mrc p15, 0, r0, c1, c0, 0
bic r0, r0, #0x00002300 @ clear bits 13, 9:8 (--V- --RS)
bic r0, r0, #0x00000087 @ clear bits 7, 2:0 (B--- -CAM)
orr r0, r0, #0x00000002 @ set bit 2 (A) Align
orr r0, r0, #0x00001000 @ set bit 12 (I) I-Cache
mcr p15, 0, r0, c1, c0, 0
@對協處理器的操作還是看不懂，暫時先不管吧，有時間研究一下ARM技術手冊的協處理器部分。

@初始化RAM時鐘，因為內存是跟開發板密切相關的，所以這部分在/開發板目錄/lowlevel_init.S中實現
mov ip, lr
@保存LR,以便正常返回,注意前面是通過BL跳到cpu_init_crit來的。
@（ARM9有37個寄存器，ARM7有27個）
37個寄存器=7個未分組寄存器（R0～R7）+ 2×（5個分組寄存器R8～R12）+6×2（R13=SP，R14=lr 分組寄存器） + 1(R15=PC) +1(CPSR) + 5(SPSR)
用途和訪問權限：
R0～R7:USR(用戶模式)、fiq（快速中斷模式）、irq（中斷模式）、svc（超級用法模式）、abt、und
R8～R12：R8_usr～R12_usr（usr，irq，svc，abt，und）
R8_fiq～R12_fiq（fiq）
R11=fp
R12=IP(從反匯編上看，fp和ip一般用于存放SP的值)
R13～R14：R13_usr R14_usr(每種模式都有自己的寄存器)
SP ～lr ：R13_fiq R14_fiq
R13_irq R14_irq
R13_svc R14_svc
R13_abt R14_abt
R13_und R14_und
R15(PC)：都可以訪問（即PC的值為當前指令的地址值加8個字節）
R16 ：（(Current Program Status Register，當前程序狀態寄存器)）
SPSR _fiq,SPSR_irq,SPSR_abt,SPSR_und(USR模式沒有)

#if defined(CONFIG_AT91RM9200EK)

#else
bl lowlevel_init

@在重定向代碼之前，必須初始化內存時序，因為重定向時需要將@flash中的代碼復制到內存中lowlevel_init在@/board/smdk2410/lowlevel_init.S中。

#endif
mov lr, ip
mov pc, lr
@返回到主程序

#endif

@這段沒有看明白，不過好像跟移植關系不是很大，先放一放。
@
@ IRQ stack frame.
@
#define S_FRAME_SIZE 72

#define S_OLD_R0 68
#define S_PSR 64
#define S_PC 60
#define S_LR 56
#define S_SP 52

#define S_IP 48
#define S_FP 44
#define S_R10 40
#define S_R9 36
#define S_R8 32
#define S_R7 28
#define S_R6 24
#define S_R5 20
#define S_R4 16
#define S_R3 12
#define S_R2 8
#define S_R1 4
#define S_R0 0

#define MODE_SVC 0x13
#define I_BIT 0x80

?

.macro bad_save_user_regs
sub sp, sp, #S_FRAME_SIZE
stmia sp, {r0 - r12} @ Calling r0-r12
ldr r2, _armboot_start
sub r2, r2, #(CONFIG_STACKSIZE)
sub r2, r2, #(CONFIG_SYS_MALLOC_LEN)
sub r2, r2, #(CONFIG_SYS_GBL_DATA_SIZE+8) @ set base 2 words into abort stack
ldmia r2, {r2 - r3} @ get pc, cpsr
add r0, sp, #S_FRAME_SIZE @ restore sp_SVC

add r5, sp, #S_SP
mov r1, lr
stmia r5, {r0 - r3} @ save sp_SVC, lr_SVC, pc, cpsr
mov r0, sp
.endm

.macro irq_save_user_regs
sub sp, sp, #S_FRAME_SIZE
stmia sp, {r0 - r12} @ Calling r0-r12
add r7, sp, #S_PC
stmdb r7, {sp, lr}^ @ Calling SP, LR
str lr, [r7, #0] @ Save calling PC
mrs r6, spsr
str r6, [r7, #4] @ Save CPSR
str r0, [r7, #8] @ Save OLD_R0
mov r0, sp
.endm

.macro irq_restore_user_regs
ldmia sp, {r0 - lr}^ @ Calling r0 - lr
mov r0, r0
ldr lr, [sp, #S_PC] @ Get PC
add sp, sp, #S_FRAME_SIZE
subs pc, lr, #4 @ return & move spsr_svc into cpsr
.endm

.macro get_bad_stack
ldr r13, _armboot_start @ setup our mode stack
sub r13, r13, #(CONFIG_STACKSIZE)
sub r13, r13, #(CONFIG_SYS_MALLOC_LEN)
sub r13, r13, #(CONFIG_SYS_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack

str lr, [r13] @ save caller lr / spsr
mrs lr, spsr
str lr, [r13, #4]

mov r13, #MODE_SVC @ prepare SVC-Mode
@ msr spsr_c, r13
msr spsr, r13
mov lr, pc
movs pc, lr
.endm

.macro get_irq_stack @ setup IRQ stack
ldr sp, IRQ_STACK_START
.endm

.macro get_fiq_stack @ setup FIQ stack
ldr sp, FIQ_STACK_START
.endm

@異常向量處理
@每一個異常向量處其實只放了一條跳轉指令（因為每個異常向量只 @有4個字節不能放太多的程序），跳到相應的異常處理程序中。
.align 5
undefined_instruction:
get_bad_stack
bad_save_user_regs
bl do_undefined_instruction

.align 5
software_interrupt:
get_bad_stack
bad_save_user_regs
bl do_software_interrupt

.align 5
prefetch_abort:
get_bad_stack
bad_save_user_regs
bl do_prefetch_abort

.align 5
data_abort:
get_bad_stack
bad_save_user_regs
bl do_data_abort

.align 5
not_used:
get_bad_stack
bad_save_user_regs
bl do_not_used

#ifdef CONFIG_USE_IRQ

.align 5
irq:
get_irq_stack
irq_save_user_regs
bl do_irq
irq_restore_user_regs

.align 5
fiq:
get_fiq_stack

irq_save_user_regs
bl do_fiq
irq_restore_user_regs

#else

.align 5
irq:
get_bad_stack
bad_save_user_regs
bl do_irq

.align 5
fiq:
get_bad_stack
bad_save_user_regs
bl do_fiq

#endif
@可知start.S的流程為：異常向量——上電復位后進入復位異常向量——跳到啟動代碼處——設置處理器進入管理模式——關閉看門狗——關閉中斷——設置時鐘分頻——關閉MMU和CACHE——進入lowlever_init.S——檢查當前代碼所處的位置，如果在FLASH中就將代碼搬移到RAM中

轉載于:https://www.cnblogs.com/pengdonglin137/p/3556527.html

總結

以上是生活随笔為你收集整理的start.s中的.balignl 16,0xdeadbeef的全部內容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網站內容還不錯，歡迎將生活随笔推薦給好友。