今天給大家分享一個需要謹慎操作的示例。

我們在實際開發中，會用到大量的測試數據，又或者老了不想干了！想要清空數據庫然后跑路了（這種違反職業道德的東西，我們不能干哦！），但涉及的表又很多，手工一張張的刪除數據方法雖然也是一種好方法，但實在是累人，所以今天給大家做一個清空表的小示例，示例非常簡單，花個半小時估計就能學會了。

第一步：建窗體

具體的設計如下圖：

第二步：添加代碼

代碼的添加也要分幾步，具體的操作如下：

添加窗體的加載事件

加載事件的作用是將數據庫中所有表在列表框中顯示

Private Sub Form_Load()

On Error GoTo ErrorHandler

Dim dbs As Object ' Database

Dim tdf As Object ' TableDef

Dim strName As String

Me.list_Table.RowSource = ""

' Me.list_Table.RowSourceType = "Value List" 列表框行來源類型設置成“值列表”，可以手工設置

' Me.list_Table.MultiSelect = 1 設置成多重選擇改成“簡單”，可以手工設置

Set dbs = CurrentDb

For Each tdf In dbs.TableDefs

strName = tdf.Name

If Not strName Like "*Sys*" And Not strName Like "TMP_*" And Not strName Like "~TMP*" Then '排除系統表與臨時表

Me.list_Table.AddItem strName '往列表中添加表名，前提先將列表框行來源類型設置成“值列表”

End If

Next

ExitHere:

Set dbs = Nothing

Exit Sub

ErrorHandler:

MsgBox Err.Description, vbCritical

Resume ExitHere

End Sub

添加復選框更新后事件

Private Sub chk_Sel_AfterUpdate()

On Error Resume Next

Dim i As Long

If Me.chk_Sel Then

For i = 0 To Me.list_Table.ListCount - 1

Me.list_Table.Selected(i) = True

Next i

Else

For i = 0 To Me.list_Table.ListCount - 1

Me.list_Table.Selected(i) = False

Next i

End If

Me.list_Table.Requery

End Sub

添加刪除按鈕的單擊事件

Private Sub btnDelete_Click()

On Error GoTo ErrorHandler

Dim varItem As Variant

Dim strSQL As String

Dim strMsg As String

strMsg = "確定要清空已選中的表？" & vbCrLf & "提示操作：謹慎操作！！！"

If MsgBox(strMsg, vbExclamation + vbOKCancel + vbDefaultButton2, "提示操作") = vbCancel Then '提示判斷是否刪除

Exit Sub

End If

For Each varItem In Me.list_Table.ItemsSelected

strSQL = "Delete from " & Me.list_Table.Column(0, varItem) '刪除語句

CurrentDb.Execute strSQL '執行刪除數據

Next

MsgBox "刪除成功，趕緊跑路吧！！！", vbInformation

ExitHere:

Exit Sub

ErrorHandler:

MsgBox Err.Description, vbCritical

Resume ExitHere

End Sub

取消按鈕的單擊事件

Private Sub btnCancel_Click()

On Error Resume Next

DoCmd.Close acForm, Me.Name

End Sub

第三步：運行

用到的幾個知識點：

列表框的使用

循環讀取所有表

刪除表中數據

到這里清空表中數據的示例就結果了，大家趕緊去試一下吧。大家也可以自行擴展一下，比如刪除數據庫中的表，連表都刪除了，還是趕緊跑吧！

皮一下就是很開心！

總結

以上是生活随笔為你收集整理的定时跑视图往另外一张表添加数据_程序猿删库跑路示例的全部內容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網站內容還不錯，歡迎將生活随笔推薦給好友。