寫過PHP的都知道，其有個extract()非常方便，可以便捷的將字典轉換為變量，當然到ASP中則要受限很多，特別是VBScript腳本，本文敘述的就是一種轉換的思路，可以實現類似的功能。

下面我就直接提供ASP版本的extract代碼吧：

'

' ASP/VBScript Dictionary extract

' Author: WangYe

' For more information please visit

'

' This code is distributed under the BSD license

'

' collection 集合或者字典，可以通過For Each訪問的

'??????????? Request.Form 或者 Request.QueryString

' specified? 指定必須存在的屬性，假如該屬性不存在，將自動創建一個

' prefix???? 每個屬性的前綴修飾

' callback?? 對于集合或者字典的每個元素(key-value)的值進行函數調用

'??????????? 函數原型：

'??????????? Function filter(key, value)

'??????????????? filter = value

'??????????? End If

'??????????? 最終值將以該函數返回的值為準

'

Function extract(collection, ByVal specified, prefix, callback)

Dim VarName, VarValue, DynObj, searchKey

specified = "," & Replace(specified, " ", "") & ","

Set DynObj = New DynamicObject

For Each key In collection

searchKey = "," & key & ","

If InStr(1, specified, searchKey, 1)>0 Then

specified = Replace(specified, searchKey, "")

If Left(specified, 1) <> "," Then

specified = "," & specified

End If

If Right(specified, 1) <> "," Then

specified = specified & ","

End If

End If

VarName = prefix & key

VarValue = collection(key)

If callback<>"" Then

VarValue = GetRef(callback)(key, VarValue)

End If

DynObj.add VarName, VarValue, PROPERTY_ACCESS_READONLY

Next

specified_array = Split(specified, ",")

Dim i

For i = LBound(specified_array) To UBound(specified_array)

If specified_array(i)<>"" Then

DynObj.add prefix & specified_array(i), "", _

PROPERTY_ACCESS_READONLY

End If

Next

Set extract = DynObj.GetObject()

End Function

再介紹下使用方法：

Dim query

Set query = extract(Request.QueryString, "name,id", "", "")

Response.Write query.name

Response.Write query.id

Set query = Nothing

訪問包含上述代碼的ASP頁面，在QueryString(就是URL問號后面的)包含name=wangye你將看到頁面輸出”wangye”，包含id=12的時候，將輸出”12″，當然你也可以同時指定兩項。

你可能發現當你Response.Write輸出name和id之外key的時候，程序報錯了，因為指定的屬性不存在，當你在查詢字符串包含這個key的時候，程序又正常了，因為有了這個key就自動建立了屬性，所以又可以直接Response.Write了，如何避免呢？

1. 通過extract()函數的specified參數，該參數是個以逗號隔開key的字符串，你可以看到剛才示例代碼中運用了這個特性，如果查詢字符串未包含相應的key，但是你又使用了這個key，只要specified列表中有，就會自動建立值為空的屬性，所以就不會報錯啦。

2. 通過返回對象的hasattr_方法進行使用前判斷，這個方法可以判斷extract()函數返回的對象是否存在相應的屬性，比如代碼有：

Dim query

Set query = extract(Request.QueryString, "name,id", "", "")

If query.hasattr_("job") Then

Response.Write "Job : " & query.job

End If

Set query = Nothing

這里job并不在我們的specified列表中，但是不帶查詢字串的直接訪問程序沒有報錯，因為我們通過hasattr_在使用前進行判斷是否存在此屬性。

3. 通過返回對象的getattr_方法進行安全訪問，這個方法會在使用前判斷指定的屬性是否存在，如果不存在則用默認值替代，詳細參考DynamicObject說明，比如代碼：

Dim query

Set query = extract(Request.QueryString, "name,id", "", "")

Response.Write "Job : " & query.getattr_("job", "No Job")

Set query = Nothing

最后再介紹下filter的使用，extract()函數的filter參數，指定的是另外一個函數名字符串，然后extract()將對每個值調用該函數進行處理，比如過去有這樣的代碼：

Dim name, job, id

name = Trim(Request.QueryString("name"))

job = Trim(Request.QueryString("job"))

id = CLng(Trim(Request.QueryString("id")))

可以看到，我們每一次都調用了Trim()函數，重復的寫多次很麻煩，而且以后如果要改變相應功能還要一個一個替換，通過filter參數我們可以這樣寫：

'

' Function filter(key, value)

'?? filter = Trim(value)

' End Function

'

Function filter(key, value)

On Error Resume Next

Select Case key

Case "id" ' 判斷ID是否是數字

If Not IsNumeric(value) Then

Exit Function

End If

If CLng(value)<1 Then

Exit Function

End If

End Select

' 最后記得讓函數返回值，該值在extract將被置為該返回值

filter = Trim(value)

If Err.Number<>0 Then

filter = ""

End If

End Function

Dim query

Set query = extract(Request.QueryString, "name,id,job", "", "filter")

Response.Write query.name

Response.Write query.job

Response.Write query.id

Set query = Nothing

剛才我們是以Request.QueryString為例子的，當然你也可以使用Request.Form來實現表單處理的更多功能，希望這篇文章能夠給你編寫ASP帶來方便:-)

總結

以上是生活随笔為你收集整理的php js vbs,VBScript版的PHP extract()函数的全部內容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網站內容還不錯，歡迎將生活随笔推薦給好友。