分享一个多线程实现[冒泡][选择][二分法]排序的例子
線程的使用規則我將會在我另一篇文章《Delphi中使用比較少的一些語法》中進行介紹，這里只開放一篇Delphi原代碼的算法：
//工程文件：Sort_MultiThread.dpr
program Sort_MultiThread;
uses
? Forms,
? SortUI in 'SortUI.pas' {fmSortUI},
? SortUC in 'SortUC.pas';
{$R *.res}
begin
? Application.Initialize;
? Application.MainFormOnTaskbar := True;
? Application.CreateForm(TfmSortUI, fmSortUI);
? Application.Run;
end.
//窗體單元文件 SortUI.pas
unit SortUI;
interface
uses
? Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
? ExtCtrls, StdCtrls, Buttons;
type
? TfmSortUI = class(TForm)
??? btnStart: TButton;
??? pbBubbleSortBox: TPaintBox;
??? pbSelectionSortBox: TPaintBox;
??? pbQuickSortBox: TPaintBox;
??? Label1: TLabel;
??? Label2: TLabel;
??? Label3: TLabel;
??? btnfresh: TBitBtn;
??? bvl1: TBevel;
??? bvl3: TBevel;
??? bvl2: TBevel;
??? procedure pbBubbleSortBoxPaint(Sender: TObject);
??? procedure pbSelectionSortBoxPaint(Sender: TObject);
??? procedure pbQuickSortBoxPaint(Sender: TObject);
??? procedure FormCreate(Sender: TObject);
??? procedure btnStartClick(Sender: TObject);
??? procedure btnfreshClick(Sender: TObject);
? private
??? ThreadsRunning: Integer;
??? procedure RandomizeArrays;
??? procedure ThreadDone(Sender: TObject);
? public
??? procedure PaintArray(Box: TPaintBox; const A: array of Integer);
? end;
var
? fmSortUI: TfmSortUI;
implementation
{$R *.dfm}
uses
? SortUC;
type
? PSortArray = ^TSortArray;
? TSortArray = array[0..114] of Integer;
var
? ArraysRandom: Boolean;????? //這個其實就是記錄數組狀態的，隨機生成完，這個狀態是true，初始化前或排序后置false
? BubbleSortArray, SelectionSortArray, QuickSortArray: TSortArray;
{ TfmSortUI }
procedure TfmSortUI.PaintArray(Box: TPaintBox; const A: array of Integer);
//根據數組值，在PaintBox 組件上繪制線段
var
? I: Integer;
begin
? with Box do
? begin
??? Canvas.Pen.Color := clRed;
??? for I := Low(A) to High(A) do
????? PaintLine(Canvas, I, A[I]); //在位置I 繪制一條長度為A[I]的線段
? end;
end;
procedure TfmSortUI.pbBubbleSortBoxPaint(Sender: TObject);
begin
? PaintArray(pbBubbleSortBox, BubbleSortArray);
end;
procedure TfmSortUI.pbSelectionSortBoxPaint(Sender: TObject);
begin
? PaintArray(pbSelectionSortBox, SelectionSortArray);
end;
procedure TfmSortUI.pbQuickSortBoxPaint(Sender: TObject);
begin
? PaintArray(pbQuickSortBox, QuickSortArray);
end;
procedure TfmSortUI.FormCreate(Sender: TObject);
begin
? RandomizeArrays; //生成隨機數組
end;
procedure TfmSortUI.btnfreshClick(Sender: TObject);
begin
? RandomizeArrays; //Self.OnCreate(self);?? 由于有ArraysRandom控制，這里可以反復執行。
end;
procedure TfmSortUI.btnStartClick(Sender: TObject);
begin
? //RandomizeArrays; //生成隨機數組
? ThreadsRunning := 3;
? //創建3 個排序線程線程
? with TBubbleSort.Create(pbBubbleSortBox, BubbleSortArray) do
??? OnTerminate := ThreadDone;
? with TSelectionSort.Create(pbSelectionSortBox, SelectionSortArray) do
??? OnTerminate := ThreadDone;
? with TQuickSort.Create(pbQuickSortBox, QuickSortArray) do
??? OnTerminate := ThreadDone;
? btnStart.Enabled := False;
end;
procedure TfmSortUI.RandomizeArrays;
var
? I: Integer;
begin
? if not ArraysRandom then
? begin
??? Randomize;
??? for I := Low(BubbleSortArray) to High(BubbleSortArray) do
????? BubbleSortArray[I] := Random(170); //生成隨機數
??? SelectionSortArray := BubbleSortArray;
??? QuickSortArray := BubbleSortArray;
??? ArraysRandom := True;
??? Repaint;
? end;
end;
procedure TfmSortUI.ThreadDone(Sender: TObject);
//線程結束處理函數
begin
? Dec(ThreadsRunning);
? if ThreadsRunning = 0 then //判斷3 個線程是否都已經結束
? begin
??? btnStart.Enabled := True;
??? ArraysRandom := False;
? end;
end;
end.
?
//窗體代碼文件SortUI.dfm
object fmSortUI: TfmSortUI
? Left = 0
? Top = 0
? Caption = 'fmSortUI'
? ClientHeight = 436
? ClientWidth = 594
? Color = clBtnFace
? Font.Charset = DEFAULT_CHARSET
? Font.Color = clWindowText
? Font.Height = -11
? Font.Name = 'Tahoma'
? Font.Style = []
? OldCreateOrder = False
? OnCreate = FormCreate
? PixelsPerInch = 96
? TextHeight = 13
? object pbBubbleSortBox: TPaintBox
??? Left = 32
??? Top = 48
??? Width = 161
??? Height = 321
??? Color = clBtnFace
??? ParentColor = False
??? OnPaint = pbBubbleSortBoxPaint
? end
? object pbSelectionSortBox: TPaintBox
??? Left = 216
??? Top = 48
??? Width = 161
??? Height = 321
??? OnPaint = pbSelectionSortBoxPaint
? end
? object pbQuickSortBox: TPaintBox
??? Left = 400
??? Top = 48
??? Width = 161
??? Height = 321
??? OnPaint = pbQuickSortBoxPaint
? end
? object Label1: TLabel
??? Left = 32
??? Top = 24
??? Width = 48
??? Height = 13
??? Caption = #20882#27873#25490#24207
? end
? object Label2: TLabel
??? Left = 216
??? Top = 24
??? Width = 48
??? Height = 13
??? Caption = #36873#25321#25490#24207
? end
? object Label3: TLabel
??? Left = 400
??? Top = 24
??? Width = 48
??? Height = 13
??? Caption = #24555#36895#25490#24207
? end
? object bvl1: TBevel
??? Left = 28
??? Top = 43
??? Width = 170
??? Height = 331
? end
? object bvl3: TBevel
??? Left = 395
??? Top = 43
??? Width = 172
??? Height = 331
? end
? object bvl2: TBevel
??? Left = 210
??? Top = 43
??? Width = 170
??? Height = 331
? end
? object btnStart: TButton
??? Left = 480
??? Top = 392
??? Width = 75
??? Height = 25
??? Caption = 'Start'
??? TabOrder = 0
??? OnClick = btnStartClick
? end
? object btnfresh: TBitBtn
??? Left = 373
??? Top = 392
??? Width = 75
??? Height = 25
??? Caption = 'fresh'
??? DoubleBuffered = True
??? ParentDoubleBuffered = False
??? TabOrder = 1
??? OnClick = btnfreshClick
? end
end
?
//線程定義及計算單元:SortUC.pas
unit SortUC;
interface
uses
? Classes, Graphics, ExtCtrls,Windows;
type
{ TSortThread }
? PSortArray = ^TSortArray;
? TSortArray = array[0..MaxInt div SizeOf(Integer) - 1] of Integer;? //這樣的定義是一個整型數組能容納最大的元素數量了。
? TSortThread = class(TThread)?????????????????????????????????????? //排序線程
? private
??? FBox: TPaintBox;???????????????????????????????????????????????? //這里僅僅是個對象指針，會在構造函數中賦值。
??? FSortArray: PSortArray;????????????????????????????????????????? //直接指向參數數組
??? FSize: Integer;????????????????????????????????????????????????? //得到參數數組的長度
??? FA, FB, FI, FJ: Integer;???????????????????????????????????????? //A,B記錄兩個線段長度，I,J記錄兩個線段位置(Y坐標)
??? procedure DoVisualSwap;????????????????????????????????????????? //交換兩段線，先抹去，再按交換位置重畫。
? protected
??? procedure Execute; override;
??? procedure VisualSwap(A, B, I, J: Integer);
??? procedure Sort(var A: array of Integer); virtual; abstract; //執行排序的抽象函數
? public
??? constructor Create(Box: TPaintBox; var SortArray: array of Integer);
? end;
{ TBubbleSort }
TBubbleSort = class(TSortThread) //冒泡排序線程
protected
? procedure Sort(var A: array of Integer); override;
end;
{ TSelectionSort }
TSelectionSort = class(TSortThread) //選擇排序線程
protected
? procedure Sort(var A: array of Integer); override;
end;
{ TQuickSort }
TQuickSort = class(TSortThread) //快速排序線程
protected
? procedure Sort(var A: array of Integer); override;
end;
procedure PaintLine(Canvas: TCanvas; I, Len: Integer);
implementation
procedure PaintLine(Canvas: TCanvas; I, Len: Integer);
//繪制線段，I 標志線段的位置，Len 標志線段的長度
begin
? Canvas.PolyLine([Point(0, I * 2 + 1), Point(Len, I * 2 + 1)]);
end;
{ TSortThread }
constructor TSortThread.Create(Box: TPaintBox; var SortArray: array of Integer);
//線程的構造函數，執行初始化工作
begin
? FBox := Box;
? FSortArray := @SortArray;?? //取參數數組的地址
? FSize := High(SortArray) - Low(SortArray) + 1;
? FreeOnTerminate := True;?????? //自動釋放線程內存。
? inherited Create(False);
end;
procedure TSortThread.DoVisualSwap;
//覆蓋交換前的線段
begin
? Sleep(2);????????????????? //這里是放慢程序便于觀看
? with FBox do
? begin
??? Canvas.Pen.Color := clBtnFace;
??? PaintLine(Canvas, FI, FA);
??? PaintLine(Canvas, FJ, FB);
??? //重新繪制交換后的線段
??? Canvas.Pen.Color := clRed;
??? PaintLine(Canvas, FI, FB);
??? PaintLine(Canvas, FJ, FA);
? end;
end;
procedure TSortThread.VisualSwap(A, B, I, J: Integer);
//重繪制交換后的線段
begin
? FA := A;
? FB := B;
? FI := I;
? FJ := J;
? Synchronize(DoVisualSwap); //通過Synchronize 完成對VCL 的訪問
end;
procedure TSortThread.Execute;
begin
? Sort(Slice(FSortArray^, FSize)); //執行排序?? 這里FSortArray指針，雖然是一個無限大的指針，但是Slice指定只返回FSize個元素。
end;
{ TBubbleSort }
procedure TBubbleSort.Sort(var A: array of Integer);
//冒泡排序
//挨著的兩個數，兩兩比對交換，讓大數沉底，這樣經過!(High(A)-Low(A)-1)次的比對，就完成排序。
var
? I, J, T: Integer;
begin
? for I := High(A) downto Low(A) do
??? for J := Low(A) to High(A) - 1 do
????? if A[J] > A[J + 1] then
????? begin
??????? VisualSwap(A[J], A[J + 1], J, J + 1); //重新繪制交換后的線段
??????? T := A[J];
??????? A[J] := A[J + 1];
??????? A[J + 1] := T;
??????? if Terminated then
????????? Exit;
????? end;
end;
{ TSelectionSort }
procedure TSelectionSort.Sort(var A: array of Integer);
//選擇排序
//這個是雙向比較，跟冒泡法差不多，首先就把最小的挑出來。只是交換的動作少很多。比對依舊是階乘級的。
var
I, J, T: Integer;
begin
? for I := Low(A) to High(A) - 1 do
??? for J := High(A) downto I + 1 do
????? if A[I] > A[J] then
????? begin
??????? VisualSwap(A[I], A[J], I, J); //重新繪制交換后的線段
??????? T := A[I];
??????? A[I] := A[J];
??????? A[J] := T;
??????? if Terminated then
????????? Exit;
????? end;
end;
{ TQuickSort }
procedure TQuickSort.Sort(var A: array of Integer);
//快速排序
//這個速度最快，也叫二分法排序，是利用一個遞歸，直接縮小范圍；在小范圍內，利用中間數向上，向下找出最接近的數交換位置
? procedure QuickSort(var A: array of Integer; iLo, iHi: Integer);
? var
??? Lo, Hi, Mid, T: Integer;
? begin
??? Lo := iLo;
??? Hi := iHi;
??? Mid := A[(Lo + Hi) div 2];
??? repeat
????? while A[Lo] < Mid do
??????? Inc(Lo);?????????????????????????? //順序情況，縮小范圍
????? while A[Hi] > Mid do
??????? Dec(Hi);?????????????????????????? //順序情況，縮小范圍
????? if Lo <= Hi then???????????????????? //這個時候A[Lo]>A[Hi]的。因為Mid失效了，已經不居中了。
????? begin
??????? VisualSwap(A[Lo], A[Hi], Lo, Hi); //重新繪制交換后的線段
??????? T := A[Lo];
??????? A[Lo] := A[Hi];
??????? A[Hi] := T;
??????? Inc(Lo);?????????????????????????? //交換以后，繼續縮小范圍。
??????? Dec(Hi);
????? end;
??? until Lo > Hi;???????????????????????? //這個時候，條件成立代表還有需要處理的子集，繼續循環。
??? if Hi > iLo then?????????????????????? //中間段處理完了，開始處理兩邊。
????? QuickSort(A, iLo, Hi);
??? if Lo < iHi then
????? QuickSort(A, Lo, iHi);
??? if Terminated then
????? Exit;
? end;
begin
? QuickSort(A, Low(A), High(A));
end;
end.
?
?
unit SortUI;
interface
uses
? Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
? ExtCtrls, StdCtrls, Buttons;
type
? TfmSortUI = class(TForm)
??? btnStart: TButton;
??? pbBubbleSortBox: TPaintBox;
??? pbSelectionSortBox: TPaintBox;
??? pbQuickSortBox: TPaintBox;
??? Label1: TLabel;
??? Label2: TLabel;
??? Label3: TLabel;
??? btnfresh: TBitBtn;
??? bvl1: TBevel;
??? bvl3: TBevel;
??? bvl2: TBevel;
??? procedure pbBubbleSortBoxPaint(Sender: TObject);
??? procedure pbSelectionSortBoxPaint(Sender: TObject);
??? procedure pbQuickSortBoxPaint(Sender: TObject);
??? procedure FormCreate(Sender: TObject);
??? procedure btnStartClick(Sender: TObject);
??? procedure btnfreshClick(Sender: TObject);
? private
??? ThreadsRunning: Integer;
??? procedure RandomizeArrays;
??? procedure ThreadDone(Sender: TObject);
? public
??? procedure PaintArray(Box: TPaintBox; const A: array of Integer);
? end;
var
? fmSortUI: TfmSortUI;
implementation
{$R *.dfm}
uses
? SortUC;
type
? PSortArray = ^TSortArray;
? TSortArray = array[0..114] of Integer;
var
? ArraysRandom: Boolean;????? //這個其實就是記錄數組狀態的，隨機生成完，這個狀態是true，初始化前或排序后置false
? BubbleSortArray, SelectionSortArray, QuickSortArray: TSortArray;
{ TfmSortUI }
procedure TfmSortUI.PaintArray(Box: TPaintBox; const A: array of Integer);
//根據數組值，在PaintBox 組件上繪制線段
var
? I: Integer;
begin
? with Box do
? begin
??? Canvas.Pen.Color := clRed;
??? for I := Low(A) to High(A) do
????? PaintLine(Canvas, I, A[I]); //在位置I 繪制一條長度為A[I]的線段
? end;
end;
procedure TfmSortUI.pbBubbleSortBoxPaint(Sender: TObject);
begin
? PaintArray(pbBubbleSortBox, BubbleSortArray);
end;
procedure TfmSortUI.pbSelectionSortBoxPaint(Sender: TObject);
begin
? PaintArray(pbSelectionSortBox, SelectionSortArray);
end;
procedure TfmSortUI.pbQuickSortBoxPaint(Sender: TObject);
begin
? PaintArray(pbQuickSortBox, QuickSortArray);
end;
procedure TfmSortUI.FormCreate(Sender: TObject);
begin
? RandomizeArrays; //生成隨機數組
end;
procedure TfmSortUI.btnfreshClick(Sender: TObject);
begin
? RandomizeArrays; //Self.OnCreate(self);?? 由于有ArraysRandom控制，這里可以反復執行。
end;
procedure TfmSortUI.btnStartClick(Sender: TObject);
begin
? //RandomizeArrays; //生成隨機數組
? ThreadsRunning := 3;
? //創建3 個排序線程線程
? with TBubbleSort.Create(pbBubbleSortBox, BubbleSortArray) do
??? OnTerminate := ThreadDone;
? with TSelectionSort.Create(pbSelectionSortBox, SelectionSortArray) do
??? OnTerminate := ThreadDone;
? with TQuickSort.Create(pbQuickSortBox, QuickSortArray) do
??? OnTerminate := ThreadDone;
? btnStart.Enabled := False;
end;
procedure TfmSortUI.RandomizeArrays;
var
? I: Integer;
begin
? if not ArraysRandom then
? begin
??? Randomize;
??? for I := Low(BubbleSortArray) to High(BubbleSortArray) do
????? BubbleSortArray[I] := Random(170); //生成隨機數
??? SelectionSortArray := BubbleSortArray;
??? QuickSortArray := BubbleSortArray;
??? ArraysRandom := True;
??? Repaint;
? end;
end;
procedure TfmSortUI.ThreadDone(Sender: TObject);
//線程結束處理函數
begin
? Dec(ThreadsRunning);
? if ThreadsRunning = 0 then //判斷3 個線程是否都已經結束
? begin
??? btnStart.Enabled := True;
??? ArraysRandom := False;
? end;
end;
end.
轉載于:https://www.cnblogs.com/Murphieston/p/6279734.html
總結
以上是生活随笔為你收集整理的分享一个多线程实现[冒泡][选择][二分法]排序的例子的全部內容，希望文章能夠幫你解決所遇到的問題。
- 上一篇： iOS之上架打包时报错：ERROR IT
- 下一篇： spark yarn任务的executo