;這是我的一款VB6軟件《愛樂影音光盤管理大師》的inno setup安裝腳本
;這個腳本生成的安裝程序請到“軟行天下”下載，網址：http://www.sharebank.com.cn/soft/soft_view.php?id=12239

; Inno Setup 下載請搜索“Inno Setup”關鍵字，國人已將這個軟件漢化了，感謝漢化作者漢化新世紀 莫名

; 請安裝Inno Setup 后繼續下一步

;將這個腳本復制到inno setup內置的編輯器內，稍加修改，即可成為你的VB6軟件的安裝腳本了
;杏軟工作室版權所有 劉付鳳，轉載時請保持文件完整

;Inno Setup 是一個免費的 Windows 安裝程序制作軟件。
;第一次發表是在 1997 年，Inno Setup 今天在功能設置和穩定性上的競爭力可能已經超過一些商業的安裝程序制作軟件
;它是真正免費的軟件，即使作為商業應用
;還有一個特點，壓縮率特別高，特別適合VB軟件，我這個安裝打包后只有3.7M，其他打包工具5M多
;安裝程序用編譯腳本的方式創建，腳本其實就是一個類似 .INI 文件格式的 ASCII 碼文本文件。 (它不象你想象的那么復雜!)
;腳本文件一般可以用安裝程序編譯器程序內置的編輯器進行編輯。在你編寫完腳本后，下一個最終步驟就是選擇安裝程序編譯器
;中的“編譯”。創建完成后，就可以運行根據你腳本編譯的安裝程序了。
;按默認，這個安裝程序創建在包含腳本文件目錄下的名為“輸出”目錄中

[Setup]
;這個段包含用于安裝程序和卸載程序的全局設置。某些提示對于你創建的任何安裝程序都是必需的
;一個必需的指示，用以指定你正在安裝的應用程序的標題。不包含版本號，與 AppVerName 指示用于同樣的目的。AppName 始終在安裝過程中顯示在安裝屏幕的左上角以及安裝向導中
AppName=愛樂影音光盤管理大師
;這個必需的指示值應該與 AppName 的值相同 (或類似)，但它還應該包含程序的版本號
AppVerName=愛樂影音光盤管理大師 V3.31
;這是所有用于在? Windows 2000/XP 中添加/刪除程序控件面板對話框中的“支持”信息中顯示的內容。這些設置是可選的，在早期的 Windows 版本中無效
AppPublisher=sinyosoft
;這是所有用于在? Windows 2000/XP 中添加/刪除程序控件面板對話框中的“支持”信息中顯示的內容。這些設置是可選的，在早期的 Windows 版本中無效
AppPublisherURL=http://www.sinyosoft.com
AppSupportURL=http://www.sinyosoft.com
AppUpdatesURL=http://www.sinyosoft.com
;這個必需的指示值是用于選擇目標位置向導面中的默認目錄名，通常它用一個目錄常量作為前綴，{pf}/SinyoCDManager將顯示:C:/Program Files/SinyoCDManager
DefaultDirName={pf}/SinyoCDManager
;這個指示的值用是在向導的選擇開始菜單文件夾頁中使用的默認開始菜單文件夾名。如果這個指示是空白或未指定，它將用“默認”作為名字
DefaultGroupName=愛樂影音光盤管理大師
;指定許可協議文件名 (可選)，用 .txt 或 .rtf (富文本) 格式，在用戶選擇程序目標目錄前顯示
LicenseFile=F:/資料保存/杏軟工作室安裝包/愛樂影音光盤管理大師/Support/Application/License.txt
;指定“自述”文件名 (可選)，用 .txt 或 .rtf (富文本) 格式，用于在安裝完成后顯示
InfoAfterFile=F:/資料保存/杏軟工作室安裝包/愛樂影音光盤管理大師/Support/Application/請先讀我.txt
;這是指定要在文件中使用的壓縮方法，以及壓縮標準
Compression=lzma
;如果設為 yes，固實壓縮將啟用。這會使所有文件一次性壓縮
SolidCompression=yes

[Tasks]
;這個段是只選的。它定義安裝程序在執行安裝期間所有由用戶定制的任務。這些任務以選項框和單選項形式在附加任務向導頁中出現
; 注意: 下面的條目包含一個中文用語 (“創建桌面快捷方式”和“添加快捷方式”)。如果需要你可以翻譯為其它語言。
Name: "desktopicon"; Description: "創建桌面快捷方式"; GroupDescription: "添加快捷方式:"; Flags: checkedonce
; 注意: 下面的條目包含一個中文用語 (“創建快速運行欄快捷方式”和“添加快捷方式”)。如果需要你可以翻譯為其它語言。
Name: "quicklaunchicon"; Description: "創建快速運行欄快捷方式"; GroupDescription: "添加快捷方式:"; Flags: checkedonce

[Files]
;這是定義安裝程序安裝文件到用戶系統中的可選文件段
;因這是VB軟件，除軟件本身包含的文件外，還必須包含相關的鏈接庫
;以下即軟件本身的文件，注：安裝目錄下有一個 "/Data" 的子目錄
Source: "F:/資料保存/杏軟工作室安裝包/愛樂影音光盤管理大師/Support/Application/CDManager.EXE"; DestDir: "{app}"; Flags: ignoreversion
Source: "F:/資料保存/杏軟工作室安裝包/愛樂影音光盤管理大師/Support/Application/Data/*"; DestDir: "{app}/Data"; Flags: ignoreversion
Source: "F:/資料保存/杏軟工作室安裝包/愛樂影音光盤管理大師/Support/Application/請先讀我.txt"; DestDir: "{app}"; Flags: ignoreversion
Source: "F:/資料保存/杏軟工作室安裝包/愛樂影音光盤管理大師/Support/Application/CDManager.exe.manifest"; DestDir: "{app}"; Flags: ignoreversion
Source: "F:/資料保存/杏軟工作室安裝包/愛樂影音光盤管理大師/Support/Application/License.txt"; DestDir: "{app}"; Flags: ignoreversion
Source: "F:/資料保存/杏軟工作室安裝包/愛樂影音光盤管理大師/Support/Application/愛樂影音光盤管理大師幫助.chm"; DestDir: "{app}"; Flags: ignoreversion
Source: "F:/資料保存/杏軟工作室安裝包/愛樂影音光盤管理大師/Support/Application/Data/*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs
; 注意: 不要在任何共享系統文件中使用“Flags: ignoreversion”

;以下是VB6 RunTime，本工作室嚴格測試過，可保證在Windows98第一版下正常運行VB6軟件
Source: "F:/資料保存/杏軟工作室安裝包/Support/vb6RunTime/ASYCFILT.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
;注意COMCAT.DLL版本號必須是4.71的，不能用5.0版本
Source: "F:/資料保存/杏軟工作室安裝包/Support/vb6RunTime/COMCAT.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:/資料保存/杏軟工作室安裝包/Support/vb6RunTime/EXPSRV.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:/資料保存/杏軟工作室安裝包/Support/vb6RunTime/MsRepl35.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:/資料保存/杏軟工作室安裝包/Support/vb6RunTime/MSVBVM60.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:/資料保存/杏軟工作室安裝包/Support/vb6RunTime/MSVCRT40.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:/資料保存/杏軟工作室安裝包/Support/vb6RunTime/OLEAUT32.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:/資料保存/杏軟工作室安裝包/Support/vb6RunTime/OLEPRO32.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:/資料保存/杏軟工作室安裝包/Support/vb6RunTime/STDOLE2.TLB"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:/資料保存/杏軟工作室安裝包/Support/vb6RunTime/VB6CHS.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
;以下是OCX控件及DAO組件
;這個軟件用的是DAO3.5、MSFLXGRD、MSCOMCT2
Source: "F:/資料保存/杏軟工作室安裝包/Support/SYSTEM/DAO350.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:/資料保存/杏軟工作室安裝包/Support/SYSTEM/DiskID32.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:/資料保存/杏軟工作室安裝包/Support/SYSTEM/FLXGDCHS.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:/資料保存/杏軟工作室安裝包/Support/SYSTEM/MSCC2CHS.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:/資料保存/杏軟工作室安裝包/Support/SYSTEM/MSCMCCHS.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:/資料保存/杏軟工作室安裝包/Support/SYSTEM/MSCOMCT2.OCX"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:/資料保存/杏軟工作室安裝包/Support/SYSTEM/MSCOMCTL.OCX"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:/資料保存/杏軟工作室安裝包/Support/SYSTEM/MSFLXGRD.OCX"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:/資料保存/杏軟工作室安裝包/Support/SYSTEM/MSJet35.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:/資料保存/杏軟工作室安裝包/Support/SYSTEM/MSJInt35.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:/資料保存/杏軟工作室安裝包/Support/SYSTEM/MSJtER35.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:/資料保存/杏軟工作室安裝包/Support/SYSTEM/MSRD2x35.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:/資料保存/杏軟工作室安裝包/Support/SYSTEM/VB5DB.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:/資料保存/杏軟工作室安裝包/Support/SYSTEM/VBAJET32.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile

;以下是本安裝特別需要的
;還用了個免費的“魔鬼XP按鈕控件”，在此一并感謝作者，在98、2K、XP-sp2下測試通過，占用資源一般
;發現了幾個BUG（不太影響使用），準備提交給作者
Source: "F:/資料保存/杏軟工作室安裝包/愛樂影音光盤管理大師/Support/UserControl/MageanButtonV1_2_0.ocx"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
;這是上一個控件需要的，必須打包上
Source: "F:/資料保存/杏軟工作室安裝包/愛樂影音光盤管理大師/Support/UserControl/Picclp32.ocx"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver

[INI]
;這是你希望安裝程序在用戶系統中設置 .INI 文件條目的可選段。
;寫一個文件“訪問我們.url”用于訪問作者網站
Filename: "{app}/訪問我們.url"; Section: "InternetShortcut"; Key: "URL"; String: "http://www.sinyosoft.com"

[Icons]
;這個可選段定義所有創建在開始菜單和/或其它位置 (比如桌面) 的快捷方式
Name: "{group}/愛樂影音光盤管理大師"; Filename: "{app}/CDManager.EXE"
Name: "{group}/愛樂影音光盤管理大師幫助"; Filename: "{app}/愛樂影音光盤管理大師幫助.chm"
Name: "{group}/請先讀我"; Filename: "{app}/請先讀我.txt"

; 注意: 下列條目包含一個中文用語 (“網站”)。如果需要你可以翻譯為其它語言。
Name: "{group}/訪問主頁"; Filename: "{app}/訪問我們.url"
Name: "{userdesktop}/愛樂影音光盤管理大師"; Filename: "{app}/CDManager.EXE"; Tasks: desktopicon
Name: "{userappdata}/Microsoft/Internet Explorer/Quick Launch/愛樂影音光盤管理大師"; Filename: "{app}/CDManager.EXE"; Tasks: quicklaunchicon

[Run]
; 注意: 下列條目包含一個中文用語 (“運行”)。如果需要你可以翻譯為其它語言。
;[Run] 段是可選的，用來指定程序完成安裝后、在安裝程序顯示最終對話框之前要執行的程序
Filename: "{app}/CDManager.EXE"; Description: "運行 愛樂影音光盤管理大師"; Flags: nowait postinstall skipifsilent

[UninstallDelete]
;這個可選段定義你想讓卸載程序刪除除用 [Files] 或 [Dirs] 條目安裝/創建外的其它文件或目錄，或由你應用程序創建的一些公共使用的 .INI 文件。卸載程序在卸載時最后一步處理這些條目
Type: files; Name: "{app}/訪問我們.url"

總結

以上是生活随笔為你收集整理的Inno Setup使用教程大全的全部內容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網站內容還不錯，歡迎將生活随笔推薦給好友。