在講AS3 Socket之前我們先來搞清幾個概念，這有助于我們更加了解網絡通信！

1、網絡中進程之間如何通信？

首要解決的問題是如何唯一標識一個進程，否則通信無從談起！在本地可以通過進程PID來唯一標識一個進程，但是在網絡中這是行不通的。其實TCP/IP協議族已經幫我們解決了這個問題，網絡層的“ip地址”可以唯一標識網絡中的主機，而傳輸層的“協議+端口”可以唯一標識主機中的應用程序（進程）。這樣利用三元組（ip地址，協議，端口）就可以標識網絡的進程了，網絡中的進程通信就可以利用這個標志與其它進程進行交互。

使用TCP/IP協議的應用程序通常采用應用編程接口：UNIX? BSD的套接字（socket）和UNIX System V的TLI（已經被淘汰），來實現網絡進程之間的通信。就目前而言，幾乎所有的應用程序都是采用socket，而現在又是網絡時代，網絡中進程通信是無處不在，這就是我為什么說“一切皆socket”。

2、什么是Socket？

上面我們已經知道網絡中的進程是通過socket來通信的，那什么是socket呢？socket起源于Unix，而Unix/Linux基本哲學之一就是“一切皆文件”，都可以用“打開open –> 讀寫write/read –> 關閉close”模式來操作。我的理解就是Socket就是該模式的一個實現，socket即是一種特殊的文件，一些socket函數就是對其進行的操作（讀/寫IO、打開、關閉），這些函數我們在后面進行介紹。

socket一詞的起源:在組網領域的首次使用是在1970年2月12日發布的文獻IETF RFC33中發現的，撰寫者為Stephen Carr、Steve Crocker和Vint Cerf。根據美國計算機歷史博物館的記載，Croker寫道：“命名空間的元素都可稱為套接字接口。一個套接字接口構成一個連接的一端，而一個連接可完全由一對套接字接口規定?！庇嬎銠C歷史博物館補充道：“這比BSD的套接字接口定義早了大約12年?！?/span>

-------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------- 好了，下面來講講AS3中的Socket編程。

我們在使用ActionScript3.0進行Socket編程的時候需要關注下面的問題,我們將在今后的學習中逐個對下面的問題進行討論,并盡量逐漸的改進我們的程序.

1.與Socket服務器建立連接.?
2.向Socket服務器發送數據.?
3.從Socket服務器讀數據.?
4.同Socket服務器進行握手,并確定收到了什么樣的數據和如何處理這些數據.?
5.與Socket服務器斷開,或者當服務器想與你斷開的時候發消息給你.?
6.處理使用Sockets時候引發的錯誤.?

1.與Socket服務器建立連接.?

解決方法:?
???? 我們通過調用Socket.connect( )或者XMLSocket.connect( )方法并監聽網絡連接的事件消息.?

討論:?
???? 連接一臺Socket服務器你需要確定兩個信息,一個是Socket服務器的域名或者IP地址,另一個是服務器監聽的端口號.?
???? 無論你使用的是Socket還是XMLSocket類的實例,連接請求都是完全的一樣的,兩個類都是使用一個名叫connect()的方法,該方法有兩個參數:?
host :?
???? 該參數為字符串類型,可以是一個域名,例如"www.example.com",也可以是一個IP地址,例如"192.168.1.101".如果Socket服務器與你該Flash影片發布的Web服務器是同一個,該參數為Null.
port :?
???? 該參數為一個表示Socket服務器監聽端口的int值.該值最小為1024.除非在服務器中有一個policy文件,用于指定允許端口號小于1024.?
???? 因為Flash Socket編程是一個異步的過程,connect()方法不會等到一個連接完成后再執行下一行代碼的執行.如果你想在一個連接完全執行完之前與一個Socket完全綁定,那么你將會得到一個意想不到的結果,并且你當前的代碼將不能工作.
???? 在嘗試一個新的Socket連接的時候我們最好先添加一個連接事件監聽器.當一個連接建立成功,Socket或者XMLSocket會發出一個連接事件,這就可以讓你知道交互已經準備好了.
???? 下面舉了一個Socket實例與本地Socket服務器的2900端口建立連接的例子:?

package {?
?? import flash.display.Sprite;?
?? import flash.events.*;?
?? import flash.net.Socket;?

?? public class SocketExample extends Sprite {?

???? private var socket:Socket;?

???? public function SocketExample(?? ) {?
?????? socket = new Socket(?? );?
?????
?????? // Add an event listener to be notified when the connection?
?????? // is made?
?????? socket.addEventListener( Event.CONNECT, onConnect );?
?????
?????? // Connect to the server?
?????? socket.connect( "localhost", 2900 );?
???? }?
???
???? private function onConnect( event:Event ):void {?
?????? trace( "The socket is now connected..." );?
???? }?
???
?? }?
}?

???? 如果你想通過XMLSocket與服務器建立連接代碼也是基本一樣的.首先你創建了一個連接事件監聽器,然后調用connect()方法.所不同的是Socket實例改為了XMLSocket:

package {?
?? import flash.display.Sprite;?
?? import flash.events.*;?
?? import flash.net.XMLSocket;?

?? public class SocketExample extends Sprite {?

???? private var socket:XMLSocket;?

???? public function SocketExample(?? ) {?
?????? socket = new XMLSocket(?? );?
?????
?????? // Add an event listener to be notified when the connection is made?
?????? socket.addEventListener( Event.CONNECT, onConnect );?
?????
?????? // Connect to the server?
?????? socket.connect( "localhost", 2900 );?
???? }?
???
???? private function onConnect( event:Event ):void {?
?????? trace( "The xml socket is now connected..." );?
???? }?
???
?? }?
}?

???? 如果連接失敗,可能是下面兩種原因的一種:一種是連接立即失敗和運行時錯誤,另一種是如果無法完成連接從而產生一個ioError或者securityError事件.關于錯誤事件處理信息的描述,我們打算改日討論.
???? 請牢記,當與一個主機建立一個Socket連接時,Flash Player要遵守如下安全沙箱規則.?
?????1.Flash的.swf文件和主機必須嚴格的在同一個域名,只有這樣才可以成功建立連接.?
???? 2.一個從網上發布的.swf文件是不可以訪問本地服務器的.?
???? 3.本地未通過認證的.swf文件是不可以訪問任何網絡資源的.?
???? 4.你想跨域訪問或者連接低于1024的端口,必須使用一個跨域策略文件.?
?????

? ? ?如果嘗試連接未認證的域或者低端口服務,這樣就違反了安全沙箱策略,同時會產生一個securityError事件.這些情況都可以通過使用一個跨域策略 文件解決.無論是Socket對象還是XMLSocket對象的策略文件,都必須在連接之前通過使用 flash.system.Security.loadPolicyFile()方法載入策略文件.具體如下:
?????Security.loadPolicyFile("http://www.rightactionscript.com/crossdomain.xml");
???? 獲得的改策略文件不僅定義了允許的域名,還定義了端口號.如果你不設置端口號,那么Flash Player默認為80端口(HTTP協議默認端口).在<allow-access-from>標簽中可以使用逗號隔開設置多個端口號.下 面這個例子就是允許訪問80和110端口.

<?xml version="1.0"?>?

<!DOCTYPE cross-domain-policy SYSTEM "http://www.macromedia.com/xml/dtds/cross-domain-policy.dtd">
<cross-domain-policy>?
?? <allow-access-from domain="*" to-ports="80,110" />?
</cross-domain-policy>?

2.向Socket服務器發送數據.?

解決方法:?
???? 對于Socket對象來說,通過是用write方法(writeByte(),writeUTFBytes( )等方法.)先向緩存區寫入數據,然后使用flush()方法發送數據.對于XMLSocket對象,使用send()方法.

討論:?
???? Socket和XMLSocket類向Socket服務器發送數據的方法是不相同的.讓我們首先看一下Socket類的方法.?
???? 當你使用Socket對象向服務器發送數據的時候,你首先要將數據寫入到一個緩沖區中.Socket類設置了一系列的方法來寫數據.每一個方法都用于寫不 同的數據類型的數據(或者不同的數據).這些方法分別是: writeBoolean( ), writeByte( ), writeBytes( ), writeDouble( ), writeFloat( ), writeInt( ), writeMultiByte( ), writeObject( ), writeShort( ), write- UnsignedInt( ), writeUTF(), 和writeUTFBytes( ). 這些方法大多數都只接受一個參數,該參數的類型同方法的名字相匹配.例如,writeBoolean()方法接受一個布爾值作為參數,而 writeByte( ), writeDouble( ), writeFloat( ), writeInt( ), writeShort( ), writeUnsignedInt( ) 方法接受一個數字型參數.writeObject()方法接受一個對象類型作為參數,但該對象必須序列化成為AMF格式.writeBytes( )方法允許你傳一個ByteArray參數,并帶有偏移量和長度兩個參數.例如,下面這段代碼,調用了一個writeBytes( )方法,該方法將ByteArray對象中的所有byt值都傳出去了(偏移量為0,長度和ByteArray數組長度等長):

socket.writeBytes(byteArray, 0, byteArray.length);?

???? writeUTF( )和writeUTFBytes( ) 方法允許你的發送字符串類型的參數.每個一個方法只接受一個字符串作為參數.writeUTFBytes( )方法簡單的將字符串作為Bytes發送.writeUTF( )方法在寫入真正數據之前,先寫入byts的數量.
???? writeMultiByte( )方法也允許字符串類型的參數,但是使用的為非默認字符集.該方法需要兩個參數:字符串和字符集名稱.在Flash和Flex的幫助文檔中有一個自持所有 字符集的列表,該列表中的標簽和描述符是一一對應的.使用標簽值作為writeMultiByte( )作為字符集.例如下面的代碼發送了一個編碼為Unicode的字符串:

socket.writeMultiByte("example", "unicode");?
???
???? 向一個Socket對象傳數值的方法完全依賴于你所有數據的類型和服務所接受數據的類型.使用一個Socket對象,你完全可以使用 ActionScript寫一個Telnet和POP mail客戶端.這兩種協議都支持ASCII字符指令.例如,在連接一個POP服務器之后,你可以通過使用USER指令指定一個用戶.下面代碼向一個 Socket對象發一條指令:

// POP servers expect a newline (\n) to execute the preceding command.?
socket.writeUTFBytes("USER exampleUsername\n");?
???
?????向一個Socket對象寫入數據其實并沒有將數據發送到Socket服務器.每調用一個write方法都向Socket對象添加一個數據.例如,下面代碼向一個Socket對象添加了四個byte的數據,但是沒有一個發出了.

socket.writeByte(1);?
socket.writeByte(5);?
socket.writeByte(4);?
socket.writeByte(8);?

?????當你想將這些累積的數據發送到Socket服務器需要調用flush()方法.flush()方法調用之后將把所有已經寫入的數據發送出去,并清空緩沖區:?

socket.flush(?? );?

???? XMLSocket類是一個非常簡單用于發送數據的API.寫于發數據都是由send()這一個方法來完成的.send()方法可以接受任何數據類型的參 數.它可以將所有的參數都轉換為一個字符串類型并發送到服務器.通常參數為一個XML對象或者一個包含數據結構類似XML數據的字符串:

xmlSocket.send(xml);?

???? 然而,準確的格式完全依賴于服務器所能夠接受的格式.如果服務器接受XML格式的數據,你必須發送XML格式的數據.如果服務器只接受URL編碼的數據,你也必須發送URL編碼的數據.


3.從Socket服務器讀數據?

解決方法:?
???? 對于Socket實例,先收到socketData事件,然后調用如下兩個方法的一個,比如,readByte()或者readInt(),在事件控制器中確定不會去讀過去的bytesAvailable.
???? 對于XMLSocket實例,先收到data事件,然后解析從事件控制器內部裝載的XML數據.?

討論:?
???? 從一個socket連接接收的數據依賴于你使用的Socket的類型.socket和XMLSocket都可以從服務器接受到數據,但是它們處于不同重量級的技術.讓我們在討論XMLSocket之前先關注下Socket類.
???? 我都知道socket在Flash中是一個異步的行為.因此,它就不能簡單的創建一個Socket連接,然后就立刻嘗試去讀取數據.read方法不能等到 從服務器傳過來數據之后在返回.換句話說,你只能在客戶端從服務器載入所有數據之后才可以讀取數據.在數據可用之前讀數據會產生一個錯誤.
???? 通過socketData事件廣播到Socket實例,這樣我們就可以知道什么時候數據可以被讀取.那么我們要為socketData事件添加一個事件監 聽器,任何時候只要有新的數據從一個socket服務器發送過來,都會觸發事件控制器.在事件處理器的內部我們寫入我們要執行的代碼去讀取和處理收到的數 據.
???? 從一個前端服務器讀取數據,Socket類為我們提供了許多不同的方法,這些方法依賴于你所讀得數據類型.例如,你可以通過readByte()方法讀一 個byte數據,或者通過一個使用readUnsignedInt()方法去讀一個無符號整數.下面這個表列出來能夠從服務器讀取的數據類型,返回值,和 read方法每次讀入的字節數.

Table:Socket read methods for various datatypes?
方法:返回值類型???????? 描述???????? 字節數?
readBoolean( ):Boolean???????? 從Socket讀取一個Boolean值.???????? 1?
readByte( ):int???????? 從Socket讀取一個byte值.???????? 1?
readDouble( ):Number???????? 從Socket讀取一個IEEE 754雙精度浮點數.???????? 8?
readFloat( ):Number???????? 從Socket讀取一個IEEE 754單精度浮點數.???????? 4?
readInt( ):int???????? 從Socket讀取一個有符號32-bit整數值.???????? 4?
readObject( ):*???????? 從Socket讀取一個AMF-encoded對象.???????? n?
readShort( ):int???????? 從Socket讀取一個有符號16-bit整數值.???????? 2?
readUnsignedByte( ):uint???????? 從Socket讀取一個無符號字節.???????? 1?
readUnsignedInt( ):uint???????? 從Socket讀取一個無符號32-bit整數???????? 4?
readUnsignedShort( ):uint???????? 從Socket讀取一個無符號16-bit整數.???????? 2?
readUTF( ):String???????? 從Socket讀取一個一個UTF8字符串.???????? n?


???? 有兩個額外的方法沒有在上面這個表中描述.它們分別是readBytes()和readUTFBytes().readBytes()方法只可以讓socket讀數據但不能返回一個值,并且該方法需要3個參數:

bytes:?
???? 一個flash.util.ByteArray實例讀取從socket中收到的數據.?
offset:?
???? 一個uint值,指定從什么位置開始讀取socket中收到數據的偏移量.默認值為0.?
length:?
???? 一個uint值,用于指定讀取bytes的數量.默認值為0,意思就是說將所有的可用的數據都放入ByteArray中.?

???? 另一個readUTFBytes()方法,只需要一個長度參數用于指定UTF-8字節的讀入數量,并且該方法會將所有讀入的字節碼轉換成為字符串類型.?

注意:在從一個Socket讀數據之前,首先要判斷bytesAvailable的屬性.如果你不知道要讀入的數據類型是什么就去讀數據的話,將會產生一個錯誤(flash.errors.EOFError).

???? 下面的例子代碼連接了一個socket服務器,讀取并顯示每次從服務器發來的數據.?

package {?
?? import flash.display.Sprite;?
?? import flash.events.ProgressEvent;?
?? import flash.net.Socket;?

?? public class SocketExample extends Sprite {?

???? private var socket:Socket;?

???? public function SocketExample(?? ) {?
?????? socket = new Socket(?? );?
?????
?????? // Listen for when data is received from the socket server?
?????? socket.addEventListener( ProgressEvent.SOCKET_DATA, onSocketData );?

?????? // Connect to the server?
?????? socket.connect( "localhost", 2900 );?
???? }?

???? private function onSocketData( eventrogressEvent ):void {?
?????? trace( "Socket received " + socket.bytesAvailable + " byte(s) of data:" );

?????? // Loop over all of the received data, and only read a byte if there?
?????? // is one available?
?????? while ( socket.bytesAvailable ) {?
???????? // Read a byte from the socket and display it?
???????? var data:int = socket.readByte(?? );?
???????? trace( data );?
?????? }?
???? }?
?? }?
}?

???? 在上面的這個例子中,如果一個socket服務器發送回一個消息(例如"hello"),當一個客戶段連入服務器就會返回并輸出下面類似的文字:?

Socket received 5 byte(s) of data:?
72?
101?
108?
108?
111?

注意:一旦數據從socket讀出,它就不能再次被讀.例如,讀一個字節之后,這個字節就不能再"放回來",只能讀后邊的字節.?

???? 當收到的數據為ASCII編碼,你可以通過readUTFBytes()方法重新構建一個字符串.readUTFBytes()方法需要知道多少個字節需要轉換為字符串.你可以使用bytesAvailable去讀所有的字節數據:

var string:String = socket.readUTFBytes(socket.bytesAvailable);?

???? XMLSocket類的動作和Socket類相比在從服務器接受數據的風格相似.兩者都是通過事件監聽器來監聽數據接收通知的,這主要取決于Flash異步的Socket實現.然而,在處理實際數據的時候有很大的不同.

???? 有個XMLSocket實例在從服務器下載完數據后分發數據事件.通過flash.events.DataEvent.DATA常量定義的數據事件包含一個data屬性,該屬性包含了從服務器收到的信息.

注意:使用XMLSocket從服務器返回的數據總是認為是一個字符串類型的數據.這樣不用為任何數據類型的數據指定讀取方法.?

???? 這些從服務器返回的數據是沒有經過任何處理的原始數據.因此,你不能通過XMLSocket連接立即使用XML,你發送和接收的都是純字符串數據.如果你期望XML,在你處理數據之前,你必須首先將這些數據轉換為一個XML的實例.
???? 下面的這段代碼在初始化的時候通過XMLSocket連接到了本地服務器的2900端口.在連接成功之后,一個<test>消息會發送到服務 器.onData事件監聽者控制從服務器返回的響應.在本例中返回字符串<response><test success='true'/></response>.你可以通過事件的data屬性發現為字符串數據,然后XML類的構造函數將 字符串轉換成為了XML實例.最后,通過使用E4X語法的XML實例的一部分信息.(關于通過使用E4X處理XML的更多詳細信息,我們需要另外討論.)

package {?
?? import flash.display.Sprite;?
?? import flash.events.Event;?
?? import flash.events.DataEvent;?
?? import flash.net.XMLSocket;?

?? public class SocketExample extends Sprite {?

???? private var xmlSocket:XMLSocket;?

???? public function SocketExample(?? ) {?
?????? xmlSocket = new XMLSocket(?? );?
?????
?????? // Connect listener to send a message to the server?
?????? // after we make a successful connection?
?????? xmlSocket.addEventListener( Event.CONNECT, onConnect );?
?????
?????? // Listen for when data is received from the socket server?
?????? xmlSocket.addEventListener( DataEvent.DATA, onData );?

?????? // Connect to the server?
?????? xmlSocket.connect( "localhost", 2900 );?
???? }?
???
???? private function onConnect( event:Event ):void {?
?????? xmlSocket.send( "<test/>" );?
???? }?

???? private function onData( eventataEvent ):void {?
?????? // The raw string returned from the server.?
?????? // It might look something like this:?
?????? // <response><test success='true'/></response>?
?????? trace( event.data );?
?????
?????? // Convert the string into XML?????
?????? var response:XML = new XML( event.data );?
?????
?????? // Using E4X, access the success attribute of the "test"?
?????? // element node in the response.?
?????? // Output: true?
?????? trace( response.test.@success );?
???? }?
?? }?
}?

注意:在data事件分發數據之前,XMLSocket實例必須從服務器收到一個表示為空的byte('\\0').也就是說,從服務器僅僅只發送所需要的字符串是不夠的,必須在結尾處加入一個表示為空的byte.

4.同Socket服務器進行握手,并確定收到了什么樣的數據和如何處理這些數據.?

解決方法:?
???? 創建不同的常量來聲明協議的狀態.使用這些常量將指定的處理函數映射到相應的狀態.在一個socketData事件控制器中,通過狀態映射調用這些函數的.?

討論:?
???? 建立Socket連接通常要處理握手這個環節.尤其是在服務器初始化需要向客戶端發送數據.然后客戶端通過一種特殊的方式相應這些數據,接著服務器因此再次響應.整個處理過程直到握手完成并且建立起一個"正常的"連接為止.

?? 處理服務器的不同響應是非難的,主要的原因是socketData事件控制器不能保存上下文的順序.也就是說,服務器的響應不會告訴你"為什么"響應, 也不告訴你這些響應數據被那個處理程序來處理.要想知道如何處理這些從服務器返回的響應不能從響應的本身來獲得,尤其在響應變化的時候.或許一個響應返回 了兩個字節碼,另一個返回了一個整數值還跟了一個雙精度浮點數.這樣看來讓響應本身處理自己是一大難題.

?? 我們通過創建一個狀態量來標注不同的上下文,服務器通過這些上下文將數據發送到客戶端.與這些狀態量都有一個相關聯的函數來處理該數據,這樣你就可以很輕松的按照當前的協議狀態去調用正確的處理函數.

???當你要與一個Socket服務器建立連接需要考慮如下幾個步驟:?
1.當與服務器連接的時候,服務器立刻返回一個標志服務器可以支持的最高協議版本號的整數值.?
2.客戶端在響應的時候會返回一個實際使用協議的版本號.?
3.服務器返回一個8byte的鑒定碼.?
4.然后客戶端將這鑒定碼返回到服務器.?
5.如果客戶端的響應不是服務器端所期望的,或者,就在這個時候該協議變成了一個常規操作模式,于是握手結束.?

?? 實際上在第四步可以在鑒定碼中包含更多的安全響應.你可以通過發送各種加密方法的密匙來代替逐個發送的鑒定碼.這通常使用在客戶端向用戶索要密碼的時候, 然后密碼成為了加密過的8byte鑒定碼.該加密過的鑒定碼接著返回到服務器.如果響應的鑒定碼匙服務器所期望的,客戶端就知道該密碼是正確的,然后同意 建立連接.

?? 實現握手框架,你首先要為處理從服務器返回的不同類型的數據分別創建常量.首先,你要從步驟1確定版本號.然后從步驟3收取鑒定碼.最后就是步驟5的常規操作模式.我們可以聲明

如下常量:?

public const DETERMINE_VERSION:int = 0;?
public const RECEIVE_CHALLENGE:int = 1;?
public const NORMAL:int = 2;?

?? 常量的值并不重要,重要的是這些值要是不同的值,兩兩之間不能有相同的整數值.?

?? 下一個步驟我們就要為不同的數據創建不同處理函數了.創建的這三個函數分別被命名為readVersion( ), readChallenge( ) 和 readNormalProtocol( ). 創建完這三個函數后,我們就必須將這三個函數分別映射到前面不同狀態常量,從而分別處理在該狀態中收到的數據.代碼如下:

stateMap = new Object(?? );?
stateMap[ DETERMINE_VERSION ] = readVersion;?
stateMap[ RECEIVE_CHALLENGE ] = readChallenge;?
stateMap[ NORMAL???????????? ] = readNormalProtocol;?

?? 最后一步是編寫socketData事件處理控制器,只有通過這樣的方式,建立在當前協議狀態之上的正確的處理函數才可以被調用.首先需要創建一個 currentState的int變量.然后使用stateMap去查詢與currentState相關聯的函數,這樣處理函數就可以被正確調用了.

var processFunc:Function = stateMap[ currentState ];?
processFunc(?? ); // Invoke the appropriate processing function?

?? 下面是一點與薄記相關的處理程序.在你的代碼中更新currentState從而確保當前協議的狀態.?
?? 前面我們所探討的握手步驟的完整的代碼如下:
package {
import flash.display.Sprite;
import flash.events.ProgressEvent;
import flash.net.Socket;
import flash.utils.ByteArray;

public class SocketExample extends Sprite {

??? // The state constants to describe the protocol
??? public const DETERMINE_VERSION:int = 0;
??? public const RECEIVE_CHALLENGE:int = 1;
??? public const NORMAL:int = 2;
???
??? // Maps a state to a processing function
??? private var stateMap:Object;
???
??? // Keeps track of the current protocol state
??? private var currentState:int;
???
??? private var socket:Socket;

??? public function SocketExample( ) {
????? // Initialzes the states map
????? stateMap = new Object( );
????? stateMap[ DETERMINE_VERSION ] = readVersion;
????? stateMap[ RECEIVE_CHALLENGE ] = readChallenge;
????? stateMap[ NORMAL??????????? ] = readNormalProtocol;
?????
????? // Initialze the current state
????? currentState = DETERMINE_VERSION;

????? // Create and connect the socket
????? socket = new Socket( );
????? socket.addEventListener( ProgressEvent.SOCKET_DATA, onSocketData );
????? socket.connect( "localhost", 2900 );
??? }
???
??? private function onSocketData( eventrogressEvent ):void {
????? // Look up the processing function based on the current state
????? var processFunc:Function = stateMap[ currentState ];
????? processFunc( );
??? }
???
??? private function readVersion( ):void {
????? // Step 1 - read the version from the server
????? var version:int = socket.readInt( );
?????
????? // Once the version is read, the next state is receiving
????? // the challenge from the server
????? currentState = RECEIVE_CHALLENGE;
?????
????? // Step 2 - write the version back to the server
????? socket.writeInt( version );
????? socket.flush( );
??? }
???
??? private function readChallenge( ):void {
????? // Step 3 - read the 8 byte challenge into a byte array
????? var bytes:ByteArray = new ByteArray( );
????? socket.readBytes( bytes, 0, 8 );
?????
????? // After the challenge is received, the next state is
????? // the normal protocol operation
????? currentState = NORMAL;
?????
????? // Step 4 - write the bytes back to the server
????? socket.writeBytes( bytes );
????? socket.flush( );
??? }
???
??? private function readNormalProtocol( ):void {
????? // Step 5 - process the normal socket messages here now that
????? // that handshaking process is complete
??? }
}
}

5.與Socket服務器斷開,或者當服務器想與你斷開的時候發消息給你.

解決方法:
????通過調用Socket.close( )或者XMLSocket.close( )方法顯性的斷開與服務器的連接.同時可以通過監聽close事件獲得服務器主動斷開的消息.

討論:
??? 通常情況下我們需要對程序進行下清理工作.比如說,你創建了一個對象,當這個對象沒有用的時候我們就要刪除它.因此,無論我們什么時候連接一個 Socket服務器,都要在我們完成了必要的任務之后顯性的斷開連接. 一直留著無用的Socket連接浪費網絡資源,應該盡量避免這種情況.如果你沒有斷開一個連接,那么這個服務器會繼續保持著這個無用的連接.這樣一來就很 快會超過了服務器最大Socket連接上線.

Socket和XMLSocket對象斷開連接的方法是一樣的.你只需要調用close()方法就可以了:

// Assume socket is a connected Socket instance
socket.close( ); // Disconnect from the server?
簡單心情,簡單生活!?
回復 | 引用 | 舉報 | 刪除2樓 yanxuanlin?? 評論時間：2008年7月9日 0時34分8秒
同樣的,XMLSocket對象斷開連接的方法一樣:

// Assume xmlSocket is a connected XMLSocket instance
xmlSocket.close( ); // Disconnect from the server

??? close()方法用于通知服務器客戶端想要斷開連接.當服務器主動斷開連接會發消息通知客戶端.可以通過調用addEventListener()方法 注冊一個close事件的一個監聽器.Socket 和 XMLSocket都是使用Event.CLOSE作為"連接斷開"事件類型的;例如:

// Add an event listener to be notified when the server disconnects
// the client
socket.addEventListener( Event.CLOSE, onClose );

注意:調用close()方法是不會觸發close事件的,只用服務器主動發起斷開才會觸發.一旦一個Socket斷開了,就無法讀寫數據了.如果你想要從新這個連接,你只能再建立個新的連接了.

6.處理使用Sockets時候引發的錯誤.

解決方法:
??? 使用try/catch處理I/O和EOF(end of file)錯誤.

討論:
??? Socket和XMLSocket類對錯誤的處理很類似.不如,當調用connect()方法的時候,在下面任何一個條件成立的情況下Socket和XMLSocket對象會拋出一個類型為SecurityError的錯誤.

* 該.swf未通過本地安全認證.
* 端口號大于655535.

??? 當調用XMLSocket對象的send()或者Socket對象的flush()的時候,如果socket還沒有連接這兩個方法都會拋出一個類型為 IOError的錯誤.盡管你可以將send()或者flush()方法放入try/catch結構塊中,你也不能依賴于try/catch結構塊作為你 應用程序的邏輯.更好的辦法是,在調用send()或者flush()方法之前使用一個if語句首先判斷一下Socket對象的connected屬性是 否為True.例如,下面的代碼使用了if語句作為程序邏輯的一部分,當Socket對象當前不是連接狀態就調用 connectToSocketServer()方法.但是我們依然需要將flush()方法放到try/catch語句塊中.通過使用 try/catch語句塊將flush()方法拋出的錯誤寫入到日志中:

if ( socket.connected ) {
??? try {
??????? socket.flush( );
??? }
??? catch( error:IOError ) {
??????? logInstance.write( "socket.flush error\n" + error );
??? }
}
else {
??? connectToSocketServer( );
}

??? 所有的Socket類的read方法都能夠拋出EOFError和IOError類型的錯誤.當你試圖讀一個數據,但是沒有任何可用數據將觸發EOF錯誤.當你試圖從一個已經關閉的Socket對象中對數據時將會拋出I/O錯誤.

??? 除了Socket和XMLSocket類的方法能夠拋出的錯誤以外,這些類的對象還會分發錯誤事件.有兩種基本的錯誤事件類型,他們分別由 socketIOError和securityError錯誤引起.IOError事件為IOErrorEvent類型,當數據發送或接收失敗觸發該事 件.SecurityError事件是SecurityErrorEvent類型,當一個Socket嘗試連接一個服務器,但由于服務器不在安全沙箱范圍 之內或者端口號小于1024的時候觸發該錯誤事件.

注意:這兩種安全策略引起的錯誤都可以通過跨域訪問策略文件解決.

總結

以上是生活随笔為你收集整理的AS3 Socket 基础知识(很全面)的全部內容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網站內容還不錯，歡迎將生活随笔推薦給好友。