該樓層疑似違規(guī)已被系統(tǒng)折疊?隱藏此樓查看此樓

主窗口：

.版本 2

.程序集 窗口程序集1

.子程序 _截取全屏_被選擇

截取全屏1 ＝ 真

載入 (窗口截屏, , 真)

.子程序 _截取指定區(qū)域_被選擇

截取全屏1 ＝ 假

載入 (窗口截屏, , 真)

第2個程序集

.版本 2

.程序集 窗口程序集2

.程序集變量 取范圍, 邏輯型

.程序集變量 取點左, 短整數(shù)型

.程序集變量 取點上, 短整數(shù)型

.程序集變量 取點右, 短整數(shù)型

.程序集變量 取點下, 短整數(shù)型

.程序集變量 畫圖片, 邏輯型

.子程序 _窗口截屏_創(chuàng)建完畢

刷新顯示 ()

窗口截屏.移動 (0, 0, 取屏幕寬度 (), 取屏幕高度 ())

畫板1.移動 (0, 0, 取屏幕寬度 (), 取屏幕高度 ())

畫板1.底圖 ＝ 快照 (, , )

標簽提示.標題 ＝ #換行符 ＋ “ A：按住鼠標左鍵拖取截屏范圍。” ＋ #換行符 ＋ #換行符 ＋ “ B：按鼠標右鍵取消”

.如果真 (截取全屏1 ＝ 真)

隱藏畫板.移動 (0, 0, 取屏幕寬度 (), 取屏幕高度 ())

畫板1.復(fù)制 (0, 0, 取屏幕寬度 (), 取屏幕高度 (), 隱藏畫板, 0, 0, )

復(fù)制圖片到剪貼板 (隱藏畫板.取圖片 (, ))

剪取圖片 ()

銷毀 ()

.如果真結(jié)束

.子程序 _畫板1_鼠標右鍵被按下, 邏輯型

.參數(shù) 橫向位置, 整數(shù)型

.參數(shù) 縱向位置, 整數(shù)型

.參數(shù) 功能鍵狀態(tài), 整數(shù)型

銷毀 ()

.子程序 _畫板1_鼠標左鍵被按下, 邏輯型

.參數(shù) 橫向位置, 整數(shù)型

.參數(shù) 縱向位置, 整數(shù)型

.參數(shù) 功能鍵狀態(tài), 整數(shù)型

畫圖片 ＝ 假

取范圍 ＝ 真

取點左 ＝ 橫向位置

取點上 ＝ 縱向位置

隱藏畫板.移動 (取點左, 取點上, 1, 1)

.子程序 _畫板1_鼠標位置被移動, 邏輯型

.參數(shù) 橫向位置, 整數(shù)型

.參數(shù) 縱向位置, 整數(shù)型

.參數(shù) 功能鍵狀態(tài), 整數(shù)型

.如果 (畫圖片 ＝ 真)

.否則

畫板1.清除 (, , , )

刷新顯示 ()

.如果結(jié)束

.如果真 (取范圍)

取點右 ＝ 橫向位置

取點下 ＝ 縱向位置

畫板1.畫矩形 (取點左, 取點上, 取點右, 取點下)

.如果真結(jié)束

.子程序 _窗口截屏_將被銷毀

取范圍 ＝ 假

.子程序 _畫板1_鼠標左鍵被放開, 邏輯型

.參數(shù) 橫向位置, 整數(shù)型

.參數(shù) 縱向位置, 整數(shù)型

.參數(shù) 功能鍵狀態(tài), 整數(shù)型

.局部變量 自身句柄, 整數(shù)型

畫圖片 ＝ 真

取范圍 ＝ 假

.如果 (橫向位置 ＜ 取點左)

取點右 ＝ 取點左

取點左 ＝ 橫向位置

.否則

取點右 ＝ 橫向位置

.如果結(jié)束

.如果 (縱向位置 ＜ 取點上)

取點下 ＝ 取點上

取點上 ＝ 縱向位置

.否則

取點下 ＝ 縱向位置

.如果結(jié)束

隱藏畫板.移動 (取點左, 取點上, 取點右 － 取點左 － 1, 取點下 － 取點上 － 1)

畫板1.復(fù)制 (取點左, 取點上, 取點右 － 取點左, 取點下 － 取點上, 隱藏畫板, 0, 0, )

復(fù)制圖片到剪貼板 (隱藏畫板.取圖片 (, ))

剪取圖片 ()

銷毀 ()

.子程序 復(fù)制圖片到剪貼板

.參數(shù) 圖片數(shù)據(jù), 字節(jié)集

.局部變量 圖片, 對象

.局部變量 圖片句柄, 整數(shù)型

圖片.創(chuàng)建圖片對象 (圖片數(shù)據(jù))

圖片句柄 ＝ 圖片.讀數(shù)值屬性 (“Handle”, )

打開剪貼板 (_啟動窗口.取窗口句柄 ())

清空剪貼板 ()

設(shè)置剪貼板數(shù)據(jù) (2, 圖片句柄)

關(guān)閉剪貼板 ()

.子程序 _標簽提示_鼠標位置被移動, 邏輯型

.參數(shù) 橫向位置, 整數(shù)型

.參數(shù) 縱向位置, 整數(shù)型

.參數(shù) 功能鍵狀態(tài), 整數(shù)型

.如果 (標簽提示.左邊 ＝ 15)

標簽提示.左邊 ＝ 窗口截屏.寬度 － 標簽提示.寬度 － 20

.否則

標簽提示.左邊 ＝ 15

.如果結(jié)束

.子程序 剪取圖片

.如果真 (信息框 (“取到圖片已保存到剪輯板中，現(xiàn)在要存為文件嗎？”, #是否鈕 ＋ #警告圖標, ) ＝ #是鈕)

通用對話框1.類型 ＝ 1

通用對話框1.過濾器 ＝ “*.bmp”

通用對話框1.默認文件后綴 ＝ “bmp”

.如果真 (通用對話框1.打開 ())

.如果 (寫到文件 (通用對話框1.文件名, 隱藏畫板.取圖片 (, )) ＝ 真)

信息框 (“保存文件成功！”, #警告圖標, )

.否則

.如果結(jié)束

.如果真結(jié)束

需要的：

.版本 2

.全局變量 截取全屏1, 邏輯型

.版本 2

.DLL命令 刪除對象, 邏輯型, , "DeleteObject"

.參數(shù) GDI對象句柄, 整數(shù)型

.DLL命令 打開剪貼板, 整數(shù)型, , "OpenClipboard"

.參數(shù) 窗口句柄, 整數(shù)型

.DLL命令 清空剪貼板, 邏輯型, , "EmptyClipboard"

.DLL命令 設(shè)置剪貼板數(shù)據(jù), 整數(shù)型, , "SetClipboardData", , 返回句柄

.參數(shù) uFormat, 整數(shù)型, , 表示的是要放進剪貼板數(shù)據(jù)的格式

.參數(shù) hMem, 整數(shù)型, , 表示數(shù)據(jù)的地址指針

.DLL命令 關(guān)閉剪貼板, 邏輯型, , "CloseClipboard", , 本函數(shù)沒有參數(shù)，事先應(yīng)該用OpenClipboard函數(shù)打開過剪貼板。

總結(jié)

以上是生活随笔為你收集整理的易语言反截图_【易语言】模仿QQ截图的全部內(nèi)容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網(wǎng)站內(nèi)容還不錯，歡迎將生活随笔推薦給好友。