錦袍繡帽躍金鞍。卷旗幡。整師還。輕騎窮追，湘尾鼓聲寒。千里塵清高會處，張翠幕，萬人看。藕絲衫袖捧雕盤。玉頹山。夜將闌。幸遇休兵，且盡玉壺寬。未用漢軍頻出塞，徒生事，斬樓蘭。
--[宋]王庭珪《江城子·錦袍繡帽躍金鞍》

在Excel中的公式非常多，要評選哪個是最應該掌握的，相信一定繞不過VLOOKUP函數。

說到VLOOKUP函數，只要是使用Excel的，相信對它一定不陌生，它的使用好處說多少都不為過，今天就重點給大家分享下VLOOKUP函數的一些常用的技巧。

首先我們先看下VLOOKUP函數的語法結構：
VLOOKUP(lookup_value,table_array,col_index_num,range_lookup)
lookup_value：查找值
table_array：查找的區域
col_index_num：返回數據在查找區域的第幾列
range_lookup：匹配模式（0為精確查找，1為模糊查找）

知道了它的函數定義，下面就給大家分享9種常用的使用技巧

技巧一、普通查找

根據姓名查詢其姓名對應的銷量，F2公式：

=VLOOKUP(E2,$B$1:$C$15,2,0)

E2:查找的內容，B1:C15為查找的區域（注意需按F4鎖定），返回的列數為2,0代表的精確查找。

技巧二、屏蔽錯誤值查找

我們在使用VLOOKUP函數時，可能會遇到查找不到值的情況，查找的結果返回為#N/A（如下情況），如果我不想顯示#N/A，而是以"查找不到"顯示，這時就要使用到IFERROR函數了。

在F2輸入公式：

=IFERROR(VLOOKUP(E2,$A$1:$C$15,3,0),"查找不到")

Iferror函數的作用為：判斷公式是否存在錯誤，如果存在錯誤，返回指定的值，否則返回公式式本身。

我們上面的公式，如果不存在錯誤，顯示公式的值，否則顯示"查找不到"

技巧三、逆向查找

VLOOKUP常用的查找方式都是從左向右查找的，那如果我想從右向左查找要如何去做呢？

比如如下根據姓名，查找對應的工號：

這時我們需要用到IF函數了，在G2輸入公式：

=VLOOKUP(E2,IF({1,0},$B$2:$B$15,$A$2:$A$15),2,0)

好多人難理解的是IF{1,0}，其實很好理解，就是把1對應的范圍和0對應的范圍組合成新的區域。

比如上面的公式，就是先把B2:B15和A2:A15的數據區域組合起來，注意查找值所在的區域需要在最前面，然后再進行查找就可以了。

技巧四、按順序返回多列值內容

比如如下，我們想根據工號，分別輸出姓名和銷量，要如何快速實現呢？

我們可以在F2輸入公式，然后向下向右填充即可

=VLOOKUP($E2,$A$1:$C$15,COLUMN(B1),0)

此公式的關鍵在于$E2的混合引用(列絕對引用，行相對引用)，以及COLUMN函數返回的需要的列數。

技巧五、多條件查詢

比如我們有如下數據，想根據姓名及所在地區查詢其對應的銷量

我們只需要在G2輸入公式，因為涉及到數組，所以輸入完成后需按Ctrl+Shift+Enter三鍵結束

=VLOOKUP(E2&F2,IF({1,0},$A$2:$A$15&$B$2:$B$15,$C$2:$C$15),2,0)

注意此處的IF{1,0}的用法是把A2:A15及B2:B5的區域合并成一個區域使用，查找值是把兩個內容合并，最終查找過程會如下樣式顯示。

技巧六、一對多查詢

假如我們想查詢如下樣式的一個部門對應的所有人員數，如果使用VLOOKUP函數要如何實現呢？

這時我們需要增加輔助列來輔助查詢了。

首先在A列增加輔助列，并在A2單元格輸入公式：

=B2&COUNTIF($B$2:B2,B2)

然后在H2輸入如下公式：

=IFERROR(VLOOKUP($G$2&ROW(A1),$A$1:$C$27,3,0),"")

這樣即把G2對應的人員名單全部提取出來了。

為方便選擇，我們可以把G2單元格的內容制作成下拉清單。

點擊【數據】-【數據驗證】-【序列】，把各部門輸入到來源中。

這時我們可以看到清單已經制作好了，當我們選擇任意部門時，即把姓名清單全部顯示出來了。

公式詳解：

=B2&COUNTIF($B$2:B2,B2)

輔助列的公式重點在于COUNTIF函數的應用，確保使用VLOOKUP函數的查找值的內容是唯一的。

COUNTIF($B$2:B2,B2)即統計B2單元格內容在區域$B$2:B2出現的次數，可以看到第一個B2是鎖定的，代表隨著公式的拖動，B2單元格內容出現的次數是依次累加的，再和B2合并，即實現了部門內容的唯一性。

比如我們看A8單元格的內容，即變成了采購部3。

當我們確認查找值為唯一值的時候，再使用VLOOKUP進行查找就很簡單了。

VLOOKUP($G$2&ROW(A1),$A$1:$C$27,3,0)

因為我們的輔助列是把部門和其出現的次數，所以此處的查找值是結合ROW函數來使用的。

$G$2&ROW(A1)：代表把G2的內容和ROW(A1)結合，我們知道ROW()函數返回其對應的行數，ROW(A1)=1,ROW(A2)=2

$A$1:$C$27:代表查詢的數據區域

3:代表需要輸出的數據內容在查找區域的第幾列

0：代表精確查找

最后我們再使用IFERROR函數，用法和上面的技巧2的用法一致，就不多講了。

技巧七、Vlookup+Match函數

我們有2019年員工每個月的銷量數據，如果我想根據員工的姓名及月份查詢其對應的銷量，要如何去做呢？

這個看起來和上面講的多條件查詢比較類似，但是可以發現上面講的是通過前兩列的條件查詢第三列的內容，而如下案例查詢的是交叉點的數據。

這時我們可以借用VLOOKUP函數和MATCH函數來實現

在C20輸入如下公式：

=VLOOKUP(A20,$A$2:$M$16,MATCH(B20,$A$2:$M$2,0),0)

同樣的姓名和月份我們可以制作成下拉選項的樣式，即可以隨意查詢銷量內容了。

MATCH函數定義：

MATCH(查找的值，查找的區域，0為精確匹配)

實現的結果是返回查找值在查找區域的第幾行第幾列

MATCH(B20,$A$2:$M$2,0)

即查詢B20的內容在A2:M2的第幾列，比如B20是"5月"，在A2:M2的第6列，再使用VLOOKUP函數返回查找值即可。

技巧八、Vlookup+通配符查找

我們在查找需要的內容時，偶爾也會遇到如下的情況，查找的值不是全稱，是簡稱，那如何通過簡稱去查詢其對應的全稱內容呢？

這時需要使用的是結合通配符使用。

我們在D2輸入如下公式：

=VLOOKUP("*"&C2&"*",$A$1:$A$6,1,0)

這里用到的是通配符"*",能代替任意數量的字符，更多用法可以看之前的文章，針對通配符有詳細的講解。

總結：

以上就是給大家分享的關于Vlookup函數使用的8個技巧，包含基本的語法結構及和其他函數搭配使用的技巧，希望對你有所幫助。

如果覺得文章對你有幫助的話，希望大家幫忙點贊加分享哦~，謝謝

本文由彩虹Excel原創，歡迎關注，帶你一起長知識！

新人創作打卡挑戰賽發博客就能抽獎！定制產品紅包拿不停！

總結

以上是生活随笔為你收集整理的c++如何将两个if函数合并_Excel中的VLOOKUP函数，8种使用技巧与你分享的全部內容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網站內容還不錯，歡迎將生活随笔推薦給好友。