LDT
先展示一下效果圖:
?
?
?
直接看代碼：
?? ? ?注意到這段代碼是在P38 ?“3.2.1海闊憑魚躍”那段代碼基礎上加上LDT得到的，新添加的代碼會著重標注出來的^_^
?
; ==========================================
; pmtest3.asm
; 編譯方法：nasm pmtest3.asm -o pmtest3.com
; ==========================================
?
%include "pm.inc" ; 常量, 宏, 以及一些說明
?
org 0100h
jmp LABEL_BEGIN
?
[SECTION .gdt]
; GDT
; ? ? ? ? ? ? ? ? ? ? ? ? ? ? ? ? ? ? ? ? 段基址, ? ? ? 段界限 ? ? , 屬性
LABEL_GDT: ? ? ? ? Descriptor ? ? ? 0, ? ? ? ? ? ? ? ? 0, 0 ? ? ; 空描述符
LABEL_DESC_NORMAL: Descriptor ? ? ? 0, ? ? ? ? ? ?0ffffh, DA_DRW ; Normal 描述符
LABEL_DESC_CODE32: Descriptor ? ? ? 0, ?SegCode32Len - 1, DA_C + DA_32 ; 非一致代碼段, 32
LABEL_DESC_CODE16: Descriptor ? ? ? 0, ? ? ? ? ? ?0ffffh, DA_C ; 非一致代碼段, 16
LABEL_DESC_DATA: ? Descriptor ? ? ? 0, ? ? ? DataLen - 1, DA_DRW+DA_DPL1 ; Data
LABEL_DESC_STACK: ?Descriptor ? ? ? 0, ? ? ? ?TopOfStack, DA_DRWA + DA_32; Stack, 32 位
LABEL_DESC_LDT: ? ?Descriptor ? ? ? 0, ? ? ? ?LDTLen - 1, DA_LDT ; LDT
LABEL_DESC_VIDEO: ?Descriptor 0B8000h, ? ? ? ? ? ?0ffffh, DA_DRW ; 顯存首地址
; GDT 結束
?
GdtLen equ $ - LABEL_GDT ; GDT長度
GdtPtr dw GdtLen - 1 ; GDT界限
dd 0 ; GDT基地址
?
; GDT 選擇子
SelectorNormal equ LABEL_DESC_NORMAL - LABEL_GDT
SelectorCode32 equ LABEL_DESC_CODE32 - LABEL_GDT
SelectorCode16 equ LABEL_DESC_CODE16 - LABEL_GDT
SelectorData equ LABEL_DESC_DATA - LABEL_GDT
SelectorStack equ LABEL_DESC_STACK - LABEL_GDT
SelectorLDT equ LABEL_DESC_LDT - LABEL_GDT
SelectorVideo equ LABEL_DESC_VIDEO - LABEL_GDT
; END of [SECTION .gdt]
?
[SECTION .data1] ; 數據段
ALIGN 32
[BITS 32]
LABEL_DATA:
SPValueInRealMode dw 0
; 字符串
PMMessage: db "In Protect Mode now. ^-^", 0 ; 進入保護模式后顯示此字符串
OffsetPMMessage equ PMMessage - $$
StrTest: db "ABCDEFGHIJKLMNOPQRSTUVWXYZ", 0
OffsetStrTest equ StrTest - $$
DataLen equ $ - LABEL_DATA
; END of [SECTION .data1]
?
?
; 全局堆棧段
[SECTION .gs]
ALIGN 32
[BITS 32]
LABEL_STACK:
times 512 db 0
?
TopOfStack equ $ - LABEL_STACK - 1
?
; END of [SECTION .gs]
?
?
[SECTION .s16]
[BITS 16]
LABEL_BEGIN:
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, 0100h
?
mov [LABEL_GO_BACK_TO_REAL+3], ax
mov [SPValueInRealMode], sp
?
; 初始化 16 位代碼段描述符
mov ax, cs
movzx eax, ax
shl eax, 4
add eax, LABEL_SEG_CODE16
mov word [LABEL_DESC_CODE16 + 2], ax
shr eax, 16
mov byte [LABEL_DESC_CODE16 + 4], al
mov byte [LABEL_DESC_CODE16 + 7], ah
?
; 初始化 32 位代碼段描述符
xor eax, eax
mov ax, cs
shl eax, 4
add eax, LABEL_SEG_CODE32
mov word [LABEL_DESC_CODE32 + 2], ax
shr eax, 16
mov byte [LABEL_DESC_CODE32 + 4], al
mov byte [LABEL_DESC_CODE32 + 7], ah
?
; 初始化數據段描述符
xor eax, eax
mov ax, ds
shl eax, 4
add eax, LABEL_DATA
mov word [LABEL_DESC_DATA + 2], ax
shr eax, 16
mov byte [LABEL_DESC_DATA + 4], al
mov byte [LABEL_DESC_DATA + 7], ah
?
; 初始化堆棧段描述符
xor eax, eax
mov ax, ds
shl eax, 4
add eax, LABEL_STACK
mov word [LABEL_DESC_STACK + 2], ax
shr eax, 16
mov byte [LABEL_DESC_STACK + 4], al
mov byte [LABEL_DESC_STACK + 7], ah
?
; 初始化 LDT 在 GDT 中的描述符
xor eax, eax
mov ax, ds
shl eax, 4
add eax, LABEL_LDT
mov word [LABEL_DESC_LDT + 2], ax
shr eax, 16
mov byte [LABEL_DESC_LDT + 4], al
mov byte [LABEL_DESC_LDT + 7], ah
?
; 初始化 LDT 中的描述符
xor eax, eax
mov ax, ds
shl eax, 4
add eax, LABEL_CODE_A
mov word [LABEL_LDT_DESC_CODEA + 2], ax
shr eax, 16
mov byte [LABEL_LDT_DESC_CODEA + 4], al
mov byte [LABEL_LDT_DESC_CODEA + 7], ah
?
; 為加載 GDTR 作準備
xor eax, eax
mov ax, ds
shl eax, 4
add eax, LABEL_GDT ; eax <- gdt 基地址
mov dword [GdtPtr + 2], eax ; [GdtPtr + 2] <- gdt 基地址
?
; 加載 GDTR
lgdt [GdtPtr]
?
; 關中斷
cli
?
; 打開地址線A20
in al, 92h
or al, 00000010b
out 92h, al
?
; 準備切換到保護模式
mov eax, cr0
or eax, 1
mov cr0, eax
?
; 真正進入保護模式
jmp dword SelectorCode32:0 ; 執行這一句會把 SelectorCode32 裝入 cs, 并跳轉到 Code32Selector:0 ?處
?
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
?
LABEL_REAL_ENTRY: ; 從保護模式跳回到實模式就到了這里
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
?
mov sp, [SPValueInRealMode]
?
in al, 92h ; ┓
and al, 11111101b ; ┣ 關閉 A20 地址線
out 92h, al ; ┛
?
sti ; 開中斷
?
mov ax, 4c00h ; ┓
int 21h ; ┛回到 DOS
; END of [SECTION .s16]
?
?
[SECTION .s32]; 32 位代碼段. 由實模式跳入.
[BITS 32]
?
LABEL_SEG_CODE32:
mov ax, SelectorData
mov ds, ax ; 數據段選擇子
mov ax, SelectorVideo
mov gs, ax ; 視頻段選擇子
?
mov ax, SelectorStack
mov ss, ax ; 堆棧段選擇子
?
mov esp, TopOfStack
?
?
; 下面顯示一個字符串
mov ah, 0Ch ; 0000: 黑底 ? ?1100: 紅字
xor esi, esi
xor edi, edi
mov esi, OffsetPMMessage ; 源數據偏移
mov edi, (80 * 10 + 0) * 2 ; 目的數據偏移。屏幕第 10 行, 第 0 列。
cld
.1:
lodsb
test al, al
jz .2
mov [gs:edi], ax
add edi, 2
jmp .1
.2: ; 顯示完畢
?
call DispReturn
?
; Load LDT ? ? ? ? ? ? ? ? ? ? ? ? ? ? ?; 即是，將選擇子SelectorLDT加載到寄存器LDTR中
mov ax, SelectorLDT
lldt ax
?
jmp SelectorLDTCodeA:0 ; 跳入局部任務
?
; ------------------------------------------------------------------------
DispReturn:
push eax
push ebx
mov eax, edi
mov bl, 160
div bl
and eax, 0FFh
inc eax
mov bl, 160
mul bl
mov edi, eax
pop ebx
pop eax
?
ret
; DispReturn 結束---------------------------------------------------------
?
SegCode32Len equ $ - LABEL_SEG_CODE32
; END of [SECTION .s32]
?
?
; 16 位代碼段. 由 32 位代碼段跳入, 跳出后到實模式
[SECTION .s16code]
ALIGN 32
[BITS 16]
LABEL_SEG_CODE16:
; 跳回實模式:
mov ax, SelectorNormal
mov ds, ax
mov es, ax
mov fs, ax
mov gs, ax
mov ss, ax
?
mov eax, cr0
and al, 11111110b
mov cr0, eax
?
LABEL_GO_BACK_TO_REAL:
jmp 0:LABEL_REAL_ENTRY ; 段地址會在程序開始處被設置成正確的值
?
Code16Len equ $ - LABEL_SEG_CODE16
?
; END of [SECTION .s16code]
?
?
; LDT
[SECTION .ldt]
ALIGN 32
LABEL_LDT:
; ? ? ? ? ? ? ? ? ? ? ? ? ? ?段基址 ? ? ? 段界限 ? ? ?屬性
LABEL_LDT_DESC_CODEA: Descriptor 0, CodeALen - 1, DA_C + DA_32 ; Code, 32 位
?
LDTLen equ $ - LABEL_LDT
?
; LDT 選擇子
SelectorLDTCodeA equ LABEL_LDT_DESC_CODEA - LABEL_LDT + SA_TIL
; END of [SECTION .ldt]
?
?
; CodeA (LDT, 32 位代碼段)
[SECTION .la]
ALIGN 32
[BITS 32]
LABEL_CODE_A:
mov ax, SelectorVideo
mov gs, ax ; 視頻段選擇子(目的)
mov edi, (80 * 12 + 0) * 2 ; 屏幕第 10 行, 第 0 列。
mov ah, 0Ch ; 0000: 黑底 ? ?1100: 紅字
mov al, 'L'
mov [gs:edi], ax
; 準備經由16位代碼段跳回實模式
jmp SelectorCode16:0
CodeALen equ $ - LABEL_CODE_A
; END of [SECTION .la]
?
?
***********************************************************************************************************************************
代碼說明及注意：
?
一、LDT段描述符屬性——DA_LDT
匯編代碼 ?
?
?98h=0000,0000,1000,0010b，也就是將
?? ? TYPE設置為0010，表示為LDT。見P36
?? ? S設置為0，表示是系統段/門描述符（如果S=1，表示是數據段/代碼段描述符）。見P36
?? ? P設置為1，表示在內存中存在。見P35
?
二、通過比較LDT和GDT來深入理解LDT
?
1.?“LDT的描述符被包含在GDT中”
?
?? ? “LDT段在GDT段中的地位”和“其他段在GDT段中的地位”平等，只不過其特定的屬性表明了他的身份——DA_LDT。他就好像一個混跡市井的賢士高人，不顯山露水，但深藏絕技；而這個絕技就是LDT段中可以完成和GDT段類似的功能——定義若干段描述符，只不過LDT中定義的段是局部的！
?? ? 關鍵代碼：
匯編代碼 ??
?? ? 下面在LDT中定義一個局部段描述符，和在GDT中定義段描述符有兩點區別：
1）在LDT中，不用定義第一個段為空段（全0）；
2）在LDT中，所有段的選擇子都需要在后面再“或操作”(“+”) SA_STL。注意到SA_STL ?equ ?4，故實際上是將LDT中定義的局部段的選擇子第2位TI置1（表示從LDT中查找段描述符；TI=0表示從GDT中找）處理!
?
匯編代碼 ??
2.?“GDT和LDT不干擾程序流程”
?? ?GDT和LDT存在的價值只是負責被查找(查找GDT直接根據GDTR——一步；而查找LDT之前由先要由GDT中LDT的描述符找到LDT的信息——兩步)，從中找到想要的段的信息。例如，在執行下面代碼時，就要查找GDT:
匯編代碼 ??
三、LDT的價值
?? ? 在上例的LDT只有一個代碼段。不難想象，我們還可以在其中增加更多的段，例如數據段、堆棧段等，這樣一來，我們可以把一個單獨的任務所用到的東西封裝在一個LDT中，這種思想是我們在后面章節中的多任務處理的一個雛形。
?
?
總結
- 上一篇： 双核不可阻挡!首款双核处理器Tegra2
- 下一篇： OCCT的拓朴结构